x11-misc/xwallpaper/xwallpaper-0.6.2-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Wallpaper setting utility for X"
   9 HOMEPAGE="https://github.com/stoeckmann/xwallpaper"
  10
  11 if [ ${PV} == "9999" ] ; then
  12         inherit git-r3
  13         EGIT_REPO_URI="https://github.com/stoeckmann/${PN}.git"
  14 else
  15         SRC_URI="https://github.com/stoeckmann/${PN}/releases/download/v${PV}/${P}.tar.xz"
  16         KEYWORDS="amd64 ~ppc64 x86"
  17 fi
  18
  19 LICENSE="ISC"
  20 SLOT="0"
  21 IUSE="jpeg png seccomp xpm"
  22
  23 RDEPEND="
  24         x11-libs/pixman
  25         x11-libs/xcb-util
  26         x11-libs/xcb-util-image
  27         jpeg? ( media-libs/libjpeg-turbo:= )
  28         png? ( media-libs/libpng:0= )
  29         seccomp? ( >=sys-libs/libseccomp-2.3.1:0= )
  30         xpm? ( x11-libs/libXpm )"
  31
  32 DEPEND="${RDEPEND}
  33         virtual/pkgconfig
  34 "
  35
  36 src_prepare() {
  37         default
  38         eautoreconf
  39 }
  40 src_configure() {
  41         local myconf=(
  42                 $(use_with jpeg)
  43                 $(use_with png)
  44                 $(use_with seccomp)
  45                 $(use_with xpm)
  46                 --with-randr
  47                 --with-zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
  48         )
  49         econf "${myconf[@]}"
  50 }