x11-misc/xsnap/xsnap-1.5.15-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="Program to interactively take a 'snapshot' of a region of the screen"
   8 HOMEPAGE="ftp://ftp.ac-grenoble.fr/ge/Xutils/"
   9 SRC_URI="ftp://ftp.ac-grenoble.fr/ge/Xutils/${P}.tar.bz2"
  10
  11 LICENSE="GPL-3+"
  12 SLOT="0"
  13 KEYWORDS="amd64 ppc x86 ~amd64-linux"
  14 IUSE=""
  15
  16 COMMON_DEPEND="
  17         media-libs/libpng:0
  18         virtual/jpeg:0
  19         x11-libs/libX11
  20         x11-libs/libXft
  21         x11-libs/libXpm
  22 "
  23 RDEPEND="
  24         ${COMMON_DEPEND}
  25         media-fonts/font-misc-misc
  26 "
  27 DEPEND="
  28         ${COMMON_DEPEND}
  29         app-text/rman
  30         dev-lang/perl
  31         x11-base/xorg-proto
  32         x11-misc/imake
  33 "
  34
  35 DOCS=( AUTHORS Changelog README )
  36 PATCHES=( "${FILESDIR}"/${P}-root_name.patch )
  37
  38 src_prepare() {
  39         default
  40
  41         sed -i \
  42                 -e 's|/usr/share/locale|$(LOCALEDIR)|g' \
  43                 -e 's|/usr/share/man/man1|$(MANDIR)|g' \
  44                 -e '/cd po.*install/s|cd.*|$(MAKE) -C po LOCALEDIR=$(LOCALEDIR) install|' \
  45                 -e '21s|.*|LOCALEDIR = /usr/share/locale|' \
  46                 Imakefile || die
  47         sed -i \
  48                 -e '/^LOCALEDIR=/d' \
  49                 po/Makefile || die
  50
  51         xmkmf || die
  52
  53         sed -i \
  54                 -e '/ CC = /d' \
  55                 -e '/ LD = /d' \
  56                 -e '/ CDEBUGFLAGS = /d' \
  57                 -e '/ CCOPTIONS = /d' \
  58                 -e 's|CPP = cpp|CPP = $(CC)|g' \
  59                 Makefile || die
  60 }
  61
  62 src_compile() {
  63         tc-export CC
  64         emake CCOPTIONS="${CFLAGS}" EXTRA_LDOPTIONS="${LDFLAGS}"
  65 }