x11-misc/xfe/xfe-1.42.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PLOCALES="
   7         bs ca cs da de el es_AR es_CO es fr hu it ja nl no pl pt_BR pt_PT ru sv tr
   8         zh_CN zh_TW
   9 "
  10 inherit autotools eutils l10n
  11
  12 DESCRIPTION="MS-Explorer-like minimalist file manager for X"
  13 HOMEPAGE="http://roland65.free.fr/xfe"
  14 SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${P}.tar.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
  19 IUSE="debug nls startup-notification"
  20
  21 RDEPEND="
  22         media-libs/libpng:0
  23         x11-libs/fox:1.6[png,truetype]
  24         x11-libs/libX11
  25         x11-libs/libXft
  26         startup-notification? ( x11-libs/startup-notification )
  27 "
  28 DEPEND="
  29         ${RDEPEND}
  30         virtual/pkgconfig
  31         nls? (
  32                 dev-util/intltool
  33                 sys-devel/gettext
  34         )
  35 "
  36
  37 DOCS=( AUTHORS BUGS ChangeLog README TODO )
  38
  39 PATCHES=( "${FILESDIR}/${PN}-1.42-use_pkgconfig_for_freetype_and_xft.patch" )
  40
  41 src_prepare() {
  42         default
  43
  44         cat >po/POTFILES.skip <<-EOF
  45         src/icons.cpp
  46         xfe.desktop.in.in
  47         xfi.desktop.in.in
  48         xfp.desktop.in.in
  49         xfv.desktop.in.in
  50         xfw.desktop.in.in
  51         EOF
  52
  53         # malformed LINGUAS file
  54         # recent intltool expects newline for every linguas
  55         sed -i \
  56                 -e '/^#/!s:\s\s*:\n:g' \
  57                 po/LINGUAS || die
  58
  59         # remove not selected locales
  60         rm_locale() { sed -i -e "/${1}/d" po/LINGUAS || die ;}
  61         l10n_for_each_disabled_locale_do rm_locale
  62
  63         sed -i \
  64                 -e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
  65                 configure.ac || die
  66
  67         eautoreconf
  68 }
  69
  70 src_configure() {
  71         local myeconfargs=(
  72                 $(use_enable debug)
  73                 $(use_enable nls)
  74                 $(use_enable startup-notification sn)
  75                 --enable-minimalflags
  76         )
  77         econf "${myeconfargs[@]}"
  78 }