x11-misc/xcb/xcb-2.4-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="Marc Lehmann's improved X Cut Buffers"
   8 HOMEPAGE="http://oldhome.schmorp.de/marc/xcb.html"
   9 SRC_URI="http://oldhome.schmorp.de/marc/data/${P}.tar.gz"
  10
  11 LICENSE="BSD"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 ~ppc x86"
  14 IUSE="motif"
  15
  16 RDEPEND="
  17         x11-libs/libX11
  18         x11-libs/libXaw
  19         x11-libs/libXext
  20         x11-libs/libXt
  21 "
  22 DEPEND="
  23         ${RDEPEND}
  24         x11-base/xorg-proto
  25         motif? ( >=x11-libs/motif-2.3:0 )
  26 "
  27
  28 src_compile() {
  29         local gui libs
  30
  31         if use motif; then
  32                 gui="-DMOTIF"
  33                 libs="-lXm -lXt -lX11"
  34         else
  35                 gui="-DATHENA"
  36                 libs="-lXaw -lXt -lXext -lX11"
  37         fi
  38
  39         emake \
  40                 -f Makefile.std xcb Xcb.ad \
  41                 CC="$(tc-getCC)" \
  42                 CPP="$(tc-getCPP)" \
  43                 CFLAGS="${CFLAGS} ${gui}" \
  44                 GUI="${gui}" \
  45                 LIBS="${libs}" \
  46                 LDFLAGS="${LDFLAGS}"
  47 }
  48
  49 src_install() {
  50         dobin xcb
  51         newman xcb.man xcb.1
  52         insinto /usr/share/X11/app-defaults
  53         newins Xcb.ad Xcb
  54 }