x11-misc/x11vnc/x11vnc-0.9.16-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 DESCRIPTION="VNC server for real X displays"
   9 HOMEPAGE="https://libvnc.github.io/"
  10 SRC_URI="https://github.com/LibVNC/x11vnc/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="crypt fbcon libressl +xcomposite +xdamage +xfixes xinerama +xrandr zeroconf"
  16
  17 COMMON_DEPEND="
  18         >=net-libs/libvncserver-0.9.8[ssl]
  19         x11-libs/libX11
  20         x11-libs/libXcursor
  21         x11-libs/libXext
  22         >=x11-libs/libXtst-1.1.0
  23         !libressl? ( dev-libs/openssl:0= )
  24         libressl? ( dev-libs/libressl:= )
  25         xcomposite? ( x11-libs/libXcomposite )
  26         xdamage? ( x11-libs/libXdamage )
  27         xfixes? ( x11-libs/libXfixes )
  28         xinerama? ( x11-libs/libXinerama )
  29         xrandr? ( x11-libs/libXrandr )
  30         zeroconf? ( >=net-dns/avahi-0.6.4 )
  31 "
  32 DEPEND="${COMMON_DEPEND}
  33         x11-base/xorg-proto
  34         x11-libs/libXt
  35 "
  36 # https://bugzilla.redhat.com/show_bug.cgi?id=920554
  37 RDEPEND="${COMMON_DEPEND}
  38         dev-lang/tk:0
  39 "
  40
  41 PATCHES=(
  42         "${FILESDIR}"/${P}-crypto.patch # https://github.com/LibVNC/x11vnc/issues/86
  43         "${FILESDIR}"/${P}-anonymous-ssl.patch # https://github.com/LibVNC/x11vnc/pull/85
  44 )
  45
  46 src_prepare() {
  47         default
  48         eautoreconf
  49 }
  50
  51 src_configure() {
  52         # --without-v4l because of missing video4linux 2.x support wrt #389079
  53         # --with-crypto --with-ssl because USE=-ssl is broken (bug #686494)
  54         econf \
  55                 --with-crypto \
  56                 --with-ssl \
  57                 --without-v4l \
  58                 --without-xkeyboard \
  59                 --without-fbpm \
  60                 --without-dpms \
  61                 $(use_with crypt) \
  62                 $(use_with fbcon fbdev) \
  63                 $(use_with xcomposite) \
  64                 $(use_with xdamage) \
  65                 $(use_with xfixes) \
  66                 $(use_with xinerama) \
  67                 $(use_with xrandr) \
  68                 $(use_with zeroconf avahi)
  69 }
  70
  71 src_install() {
  72         default
  73         newinitd "${FILESDIR}/x11vnc.init.d" x11vnc
  74         newconfd "${FILESDIR}/x11vnc.conf.d" x11vnc
  75 }