x11-misc/x11vnc/x11vnc-0.9.14_p20161013.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools vcs-snapshot
   6
   7 DESCRIPTION="A VNC server for real X displays"
   8 HOMEPAGE="https://libvnc.github.io/"
   9 SRC_URI="https://github.com/LibVNC/x11vnc/archive/e191071c1f375d04ba8f955ea0a30292a485999e.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
  14 IUSE="crypt fbcon libressl ssl xinerama zeroconf"
  15
  16 RDEPEND=">=net-libs/libvncserver-0.9.8[ssl?]
  17         x11-libs/libX11
  18         x11-libs/libXdamage
  19         x11-libs/libXext
  20         x11-libs/libXfixes
  21         x11-libs/libXrandr
  22         >=x11-libs/libXtst-1.1.0
  23         ssl? (
  24                 !libressl? ( dev-libs/openssl:0= )
  25                 libressl? ( dev-libs/libressl:= )
  26         )
  27         xinerama? ( x11-libs/libXinerama )
  28         zeroconf? ( >=net-dns/avahi-0.6.4 )
  29 "
  30 DEPEND="${RDEPEND}
  31         x11-base/xorg-proto
  32         x11-libs/libXt"
  33
  34 src_prepare() {
  35         default
  36         eautoreconf
  37 }
  38
  39 src_configure() {
  40         # --without-v4l because of missing video4linux 2.x support wrt #389079
  41         econf \
  42                 $(use_with crypt) \
  43                 $(use_with fbcon fbdev) \
  44                 $(use_with ssl) \
  45                 $(use_with ssl crypto) \
  46                 --without-v4l \
  47                 $(use_with xinerama) \
  48                 $(use_with zeroconf avahi)
  49 }
  50
  51 src_install() {
  52         default
  53         doinitd "${FILESDIR}/x11vnc.init.d"
  54         doconfd "${FILESDIR}/x11vnc.conf.d"
  55 }