x11-misc/tint2/tint2-16.6.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils gnome2-utils vcs-snapshot
   7
   8 DESCRIPTION="tint2 is a lightweight panel/taskbar for Linux."
   9 HOMEPAGE="https://gitlab.com/o9000/tint2"
  10 SRC_URI="https://gitlab.com/o9000/${PN}/repository/archive.tar.gz?ref=v${PV} -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86"
  15 IUSE="battery svg startup-notification tint2conf"
  16
  17 DEPEND="
  18         dev-libs/glib:2
  19         svg? ( gnome-base/librsvg:2 )
  20         >=media-libs/imlib2-1.4.2[X,png]
  21         x11-libs/cairo[X]
  22         x11-libs/pango
  23         tint2conf? ( x11-libs/gtk+:2 )
  24         x11-libs/libX11
  25         x11-libs/libXcomposite
  26         x11-libs/libXdamage
  27         x11-libs/libXinerama
  28         >=x11-libs/libXrandr-1.3
  29         x11-libs/libXrender
  30         startup-notification? ( x11-libs/startup-notification )
  31 "
  32 RDEPEND="${DEPEND}"
  33
  34 src_configure() {
  35         local mycmakeargs=(
  36                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
  37                 -DENABLE_BATTERY="$(usex battery)"
  38                 -DENABLE_TINT2CONF="$(usex tint2conf)"
  39                 -DENABLE_SN="$(usex startup-notification)"
  40                 -DENABLE_RSVG="$(usex svg)"
  41         )
  42
  43         cmake-utils_src_configure
  44 }
  45
  46 src_install() {
  47         cmake-utils_src_install
  48 }
  49
  50 pkg_preinst() {
  51         gnome2_icon_savelist
  52 }
  53
  54 pkg_postinst() {
  55         gnome2_icon_cache_update
  56 }
  57
  58 pkg_postrm() {
  59         gnome2_icon_cache_update
  60 }