x11-misc/spacefm/spacefm-1.0.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2-utils linux-info xdg-utils
   7
   8 DESCRIPTION="A multi-panel tabbed file manager"
   9 HOMEPAGE="https://ignorantguru.github.com/spacefm/"
  10 if [[ ${PV} == *9999* ]]; then
  11         EGIT_REPO_URI="https://github.com/IgnorantGuru/${PN}.git"
  12         EGIT_BRANCH="next"
  13         inherit git-r3
  14 else
  15         KEYWORDS="amd64 x86"
  16         SRC_URI="https://github.com/IgnorantGuru/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  17 fi
  18
  19 LICENSE="GPL-2 LGPL-2.1"
  20 SLOT="0"
  21 IUSE="gtk2 +gtk3 +startup-notification +video-thumbnails"
  22
  23 RDEPEND="dev-libs/glib:2
  24         dev-util/desktop-file-utils
  25         >=virtual/udev-143
  26         virtual/freedesktop-icon-theme
  27         x11-libs/cairo
  28         x11-libs/gdk-pixbuf
  29         x11-libs/pango
  30         x11-libs/libX11
  31         x11-misc/shared-mime-info
  32         gtk2? ( gtk3? ( x11-libs/gtk+:3 ) !gtk3? ( x11-libs/gtk+:2 ) )
  33         !gtk2? ( x11-libs/gtk+:3 )
  34         startup-notification? ( x11-libs/startup-notification )
  35         video-thumbnails? ( media-video/ffmpegthumbnailer )"
  36 DEPEND="${RDEPEND}
  37         dev-util/intltool
  38         sys-devel/gettext
  39         virtual/pkgconfig"
  40
  41 PATCHES=( "${FILESDIR}"/${PN}-9999-include-sysmacros.patch )
  42
  43 src_configure() {
  44         econf \
  45                 $(use_enable startup-notification) \
  46                 $(use_enable video-thumbnails) \
  47                 --disable-hal \
  48                 --enable-inotify \
  49                 --disable-pixmaps \
  50                 $(use_with gtk3 gtk3 "yes")
  51 }
  52
  53 pkg_postinst() {
  54         xdg_desktop_database_update
  55         xdg_mimeinfo_database_update
  56         gnome2_icon_cache_update
  57
  58         einfo
  59         elog "To mount as non-root user you need one of the following:"
  60         elog "  sys-apps/udevil (recommended, see below)"
  61         elog "  sys-apps/pmount"
  62         elog "  sys-fs/udisks:0"
  63         elog "  sys-fs/udisks:2"
  64         elog "To support ftp/nfs/smb/ssh URLs in the path bar you need:"
  65         elog "  sys-apps/udevil"
  66         elog "To perform as root functionality you need one of the following:"
  67         elog "  x11-misc/ktsuss"
  68         elog "  kde-plasma/kde-cli-tools[kdesu]"
  69         elog "Other optional dependencies:"
  70         elog "  sys-apps/dbus"
  71         elog "  sys-process/lsof (device processes)"
  72         elog "  virtual/eject (eject media)"
  73         einfo
  74         if ! has_version 'sys-fs/udisks' ; then
  75                 elog "When using SpaceFM without udisks, and without the udisks-daemon running,"
  76                 elog "you may need to enable kernel polling for device media changes to be detected."
  77                 elog "See /usr/share/doc/${PF}/html/spacefm-manual-en.html#devices-kernpoll"
  78                 has_version '<virtual/udev-173' && ewarn "You need at least udev-173"
  79                 kernel_is lt 2 6 38 && ewarn "You need at least kernel 2.6.38"
  80                 einfo
  81         fi
  82 }
  83
  84 pkg_postrm() {
  85         xdg_desktop_database_update
  86         xdg_mimeinfo_database_update
  87         gnome2_icon_cache_update
  88 }