x11-misc/spacefm/spacefm-0.9.3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit fdo-mime gnome2-utils linux-info
   8
   9 DESCRIPTION="A multi-panel tabbed file manager"
  10 HOMEPAGE="http://ignorantguru.github.com/spacefm/"
  11 SRC_URI="https://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz
  12         mirror://sourceforge/${PN}/${P}.tar.xz"
  13
  14 LICENSE="GPL-2 LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="+startup-notification"
  18
  19 RDEPEND="dev-libs/glib:2
  20         dev-util/desktop-file-utils
  21         >=virtual/udev-143
  22         virtual/freedesktop-icon-theme
  23         x11-libs/cairo
  24         x11-libs/gdk-pixbuf
  25         x11-libs/gtk+:3
  26         x11-libs/pango
  27         x11-libs/libX11
  28         x11-misc/shared-mime-info
  29         startup-notification? ( x11-libs/startup-notification )"
  30 DEPEND="${RDEPEND}
  31         dev-util/intltool
  32         virtual/pkgconfig
  33         sys-devel/gettext"
  34
  35 src_configure() {
  36         econf \
  37                 --htmldir=/usr/share/doc/${PF}/html \
  38                 $(use_enable startup-notification) \
  39                 --disable-hal \
  40                 --enable-inotify \
  41                 --disable-pixmaps \
  42                 --with-gtk3=yes
  43 }
  44
  45 pkg_preinst() {
  46         gnome2_icon_savelist
  47 }
  48
  49 pkg_postinst() {
  50         fdo-mime_desktop_database_update
  51         fdo-mime_mime_database_update
  52         gnome2_icon_cache_update
  53
  54         einfo
  55         elog "To mount as non-root user you need one of the following:"
  56         elog "  sys-apps/udevil (recommended, see below)"
  57         elog "  sys-apps/pmount"
  58         elog "  sys-fs/udisks:0"
  59         elog "  sys-fs/udisks:2"
  60         elog "To support ftp/nfs/smb/ssh URLs in the path bar you need:"
  61         elog "  sys-apps/udevil"
  62         elog "To perform as root functionality you need one of the following:"
  63         elog "  x11-misc/ktsuss"
  64         elog "  x11-libs/gksu"
  65         elog "  kde-apps/kdesu"
  66         elog "Other optional dependencies:"
  67         elog "  sys-apps/dbus"
  68         elog "  sys-process/lsof (device processes)"
  69         elog "  virtual/eject (eject media)"
  70         einfo
  71         if ! has_version 'sys-fs/udisks' ; then
  72                 elog "When using SpaceFM without udisks, and without the udisks-daemon running,"
  73                 elog "you may need to enable kernel polling for device media changes to be detected."
  74                 elog "See /usr/share/doc/${PF}/html/spacefm-manual-en.html#devices-kernpoll"
  75                 has_version '<virtual/udev-173' && ewarn "You need at least udev-173"
  76                 kernel_is lt 2 6 38 && ewarn "You need at least kernel 2.6.38"
  77                 einfo
  78         fi
  79 }
  80
  81 pkg_postrm() {
  82         fdo-mime_desktop_database_update
  83         fdo-mime_mime_database_update
  84         gnome2_icon_cache_update
  85 }