x11-misc/snixembed/snixembed-0.2.2.ebuild

   1 # Copyright 2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit vala
   7
   8 DESCRIPTION="Proxy StatusNotifierItems as XEmbedded systemtray-spec icons"
   9 HOMEPAGE="https://git.sr.ht/~steef/snixembed"
  10 SRC_URI="https://git.sr.ht/~steef/snixembed/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="ISC"
  13 SLOT="0"
  14 KEYWORDS="~amd64"
  15 IUSE="doc"
  16
  17 DEPEND="dev-libs/glib:2
  18         dev-libs/libdbusmenu[gtk3]
  19         x11-libs/gtk+:3"
  20 RDEPEND="${DEPEND}"
  21 BDEPEND="$(vala_depend)
  22         virtual/pkgconfig
  23         doc? ( dev-lang/vala[valadoc] )"
  24
  25 src_prepare() {
  26         default
  27
  28         use doc && local VALA_USE_DEPEND="valadoc"
  29         vala_src_prepare
  30
  31         sed -e "s: .git/HEAD .git/index::" \
  32                 -e "s:\$(shell git describe --always --tags --dirty):${PV}:" \
  33                 -e "s:valac :${VALAC} :" \
  34                 -e "s:valadoc :${VALADOC} :" \
  35                 -i makefile || die
  36 }
  37
  38 src_compile() {
  39         default
  40         use doc && emake doc
  41 }
  42
  43 src_install() {
  44         emake DESTDIR="${D}" PREFIX="${EPREFIX}" BINDIR="/usr/bin" install
  45         use doc && HTML_DOCS=( doc/. )
  46         einstalldocs
  47 }