x11-misc/slock/slock-1.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit fcaps savedconfig toolchain-funcs
   6
   7 DESCRIPTION="simple X display locker"
   8 HOMEPAGE="https://tools.suckless.org/slock"
   9 SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="amd64 hppa x86"
  14
  15 RDEPEND="
  16         x11-libs/libX11
  17         x11-libs/libXext
  18         x11-libs/libXrandr
  19 "
  20 DEPEND="
  21         ${RDEPEND}
  22         x11-base/xorg-proto
  23 "
  24
  25 src_prepare() {
  26         default
  27
  28         sed -i \
  29                 -e '/^CFLAGS/{s: -Os::g; s:= :+= :g}' \
  30                 -e '/^CC/d' \
  31                 -e '/^LDFLAGS/{s:-s::g; s:= :+= :g}' \
  32                 config.mk || die
  33         sed -i \
  34                 -e 's|@${CC}|$(CC)|g' \
  35                 Makefile || die
  36
  37         if use elibc_FreeBSD; then
  38                 sed -i -e 's/-DHAVE_SHADOW_H//' config.mk || die
  39         fi
  40
  41         restore_config config.h
  42
  43         tc-export CC
  44 }
  45
  46 src_compile() { emake slock; }
  47
  48 src_install() {
  49         dobin slock
  50         save_config config.h
  51 }
  52
  53 pkg_postinst() {
  54         # cap_dac_read_search used to be enough for shadow access
  55         # but now slock wants to write to /proc/self/oom_score_adj
  56         # and for that it needs:
  57         fcaps \
  58                 cap_dac_override,cap_setgid,cap_setuid,cap_sys_resource \
  59                 /usr/bin/slock
  60
  61         savedconfig_pkg_postinst
  62 }