x11-misc/sddm/sddm-0.15.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils systemd user
   7
   8 DESCRIPTION="Simple Desktop Display Manager"
   9 HOMEPAGE="https://github.com/sddm/sddm"
  10 SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
  11 KEYWORDS="amd64 ~arm ~arm64 x86"
  12
  13 LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
  14 SLOT="0"
  15 IUSE="consolekit elogind +pam systemd"
  16
  17 REQUIRED_USE="?? ( elogind systemd )"
  18
  19 RDEPEND="
  20         >=dev-qt/qtcore-5.6:5
  21         >=dev-qt/qtdbus-5.6:5
  22         >=dev-qt/qtgui-5.6:5
  23         >=dev-qt/qtdeclarative-5.6:5
  24         >=dev-qt/qtnetwork-5.6:5
  25         >=x11-base/xorg-server-1.15.1
  26         x11-libs/libxcb[xkb]
  27         consolekit? ( >=sys-auth/consolekit-0.9.4 )
  28         elogind? ( sys-auth/elogind )
  29         pam? ( sys-libs/pam )
  30         systemd? ( sys-apps/systemd:= )
  31         !systemd? ( sys-power/upower )"
  32
  33 DEPEND="${RDEPEND}
  34         dev-python/docutils
  35         >=dev-qt/linguist-tools-5.6:5
  36         >=dev-qt/qttest-5.6:5
  37         kde-frameworks/extra-cmake-modules
  38         virtual/pkgconfig"
  39
  40 # fix for flags handling and bug 563108
  41 PATCHES=( "${FILESDIR}/${PN}-0.12.0-respect-user-flags.patch" )
  42
  43 src_prepare() {
  44         use consolekit && eapply "${FILESDIR}/${PN}-0.14.0-consolekit.patch"
  45         cmake-utils_src_prepare
  46 }
  47
  48 src_configure() {
  49         local mycmakeargs=(
  50                 -DENABLE_PAM=$(usex pam)
  51                 -DNO_SYSTEMD=$(usex '!systemd')
  52                 -DUSE_ELOGIND=$(usex 'elogind')
  53                 -DBUILD_MAN_PAGES=ON
  54                 -DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
  55         )
  56         cmake-utils_src_configure
  57 }
  58
  59 pkg_postinst() {
  60         enewgroup ${PN}
  61         enewuser ${PN} -1 -1 /var/lib/${PN} ${PN},video
  62
  63         systemd_reenable sddm.service
  64 }