x11-misc/qtfm/qtfm-5.9-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit qmake-utils xdg-utils
   7
   8 DESCRIPTION="A small, lightweight file manager for desktops based on pure Qt"
   9 HOMEPAGE="http://www.qtfm.org/"
  10 SRC_URI="https://dev.gentoo.org/~jer/${P}.zip"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15
  16 RDEPEND="
  17         dev-qt/qtcore:5
  18         dev-qt/qtgui:5
  19         dev-qt/qtnetwork:5
  20         dev-qt/qtwidgets:5
  21         sys-apps/file
  22 "
  23 DEPEND="${RDEPEND}
  24         app-arch/unzip
  25         dev-qt/linguist-tools:5
  26 "
  27
  28 PATCHES=( "${FILESDIR}"/${PN}-5.5-gcc6.patch )
  29
  30 S=${WORKDIR}/${PN}-master
  31
  32 src_prepare() {
  33         rm translations/${PN}_XX.ts || die
  34
  35         default
  36
  37         sed -i \
  38                 -e '/MimeType=/s|$|;|' \
  39                 -e '/Categories=/s|$|;System;FileTools;|' \
  40                 ${PN}.desktop || die
  41
  42         sed -i -e '/^INSTALLS/s/docs//' ${PN}.pro || die
  43 }
  44
  45 src_configure() {
  46         "$(qt5_get_bindir)"/lrelease translations/*.ts || die
  47         eqmake5
  48 }
  49
  50 src_install() {
  51         emake INSTALL_ROOT="${D}" install
  52         einstalldocs
  53 }
  54
  55 pkg_postinst() {
  56         xdg_desktop_database_update
  57 }
  58
  59 pkg_postrm() {
  60         xdg_desktop_database_update
  61 }