x11-misc/qterm/qterm-0.7.3.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit cmake-utils gnome2-utils xdg-utils
   7
   8 DESCRIPTION="A BBS client based on Qt"
   9 HOMEPAGE="https://github.com/qterm/qterm"
  10 SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="libressl"
  16
  17 RDEPEND="dev-qt/qtcore:5
  18         dev-qt/qtgui:5
  19         dev-qt/qtmultimedia:5
  20         dev-qt/qtnetwork:5
  21         dev-qt/qtprintsupport:5
  22         dev-qt/qtscript:5[scripttools]
  23         dev-qt/qtwidgets:5
  24         dev-qt/qtxml:5
  25         x11-libs/libX11
  26         !libressl? ( dev-libs/openssl:0= )
  27         libressl? ( dev-libs/libressl:= )"
  28 DEPEND="${RDEPEND}
  29         dev-qt/linguist-tools:5
  30         dev-qt/qthelp:5
  31         x11-base/xorg-proto"
  32
  33 PATCHES=( "${FILESDIR}"/${PN}-libressl.patch )
  34 DOCS=( README.rst RELEASE_NOTES TODO doc/script.txt )
  35
  36 src_prepare() {
  37         # file collision with sys-cluster/torque, bug #176533
  38         sed -i "/PROGRAME /s/qterm/QTerm/" CMakeLists.txt
  39         sed -i "s/Exec=qterm/Exec=QTerm/" src/${PN}.desktop
  40
  41         cmake-utils_src_prepare
  42         xdg_environment_reset
  43 }
  44
  45 src_configure() {
  46         local mycmakeargs=(
  47                 -DQT5=ON
  48         )
  49         cmake-utils_src_configure
  50 }
  51
  52 pkg_postinst() {
  53         gnome2_icon_cache_update
  54 }
  55
  56 pkg_postrm() {
  57         gnome2_icon_cache_update
  58 }