x11-misc/qt5ct/qt5ct-0.29-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit qmake-utils
   8
   9 DESCRIPTION="Qt5 configuration tool, similar to qtconfig for Qt4"
  10 HOMEPAGE="https://sourceforge.net/projects/qt5ct/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  12
  13 LICENSE="BSD-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64"
  16 IUSE="+systray"
  17
  18 RDEPEND="
  19         dev-qt/qtcore:5
  20         dev-qt/qtgui:5=
  21         dev-qt/qtwidgets:5
  22         systray? ( dev-qt/qtgui:5[dbus] )
  23 "
  24 DEPEND="${RDEPEND}
  25         dev-qt/linguist-tools:5
  26 "
  27
  28 PATCHES=( "${FILESDIR}/${P}-fix-kde-styles.patch" )
  29
  30 src_configure() {
  31         eqmake5 DEFINES="$(usex systray '' QT_NO_SYSTEMTRAYICON)" ${PN}.pro
  32 }
  33
  34 src_install() {
  35         emake INSTALL_ROOT="${D}" install
  36         einstalldocs
  37
  38         echo 'QT_QPA_PLATFORMTHEME=qt5ct' > "${T}"/98${PN} || die
  39         doenvd "${T}"/98${PN}
  40 }
  41
  42 pkg_postinst() {
  43         if [[ -z ${REPLACING_VERSIONS} ]]; then
  44                 ewarn "qt5ct configuration won't be applied to the currently running sessions."
  45                 ewarn "Please relogin."
  46         fi
  47         if ! has_version 'dev-qt/qtsvg:5'; then
  48                 elog
  49                 elog "For SVG icon themes, please install 'dev-qt/qtsvg:5'."
  50                 elog
  51         fi
  52 }