x11-misc/libinput-gestures/libinput-gestures-2.34.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python{3_4,3_5,3_6} )
   7
   8 inherit gnome2-utils python-single-r1
   9
  10 DESCRIPTION="Actions gestures on your touchpad using libinput"
  11 HOMEPAGE="https://github.com/bulletmark/libinput-gestures"
  12 if [[ ${PV} == *9999 ]] ; then
  13         inherit git-r3
  14         EGIT_REPO_URI="https://github.com/bulletmark/${PN}.git"
  15 else
  16         SRC_URI="https://github.com/bulletmark/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  17         KEYWORDS="~amd64 ~x86"
  18 fi
  19
  20 LICENSE="GPL-3"
  21 SLOT="0"
  22 IUSE="test"
  23 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  24
  25 RDEPEND="${PYTHON_DEPS}
  26         >=dev-libs/libinput-1.8.0
  27         x11-misc/xdotool
  28         x11-misc/wmctrl"
  29 DEPEND=">=dev-libs/libinput-1.8.0
  30         dev-util/desktop-file-utils
  31         test? ( dev-python/flake8[${PYTHON_USEDEP}] )"
  32
  33 src_prepare() {
  34         default
  35
  36         # Fix docdir installation path
  37         sed '/^DOCDIR/s@$NAME@${PF}@' -i libinput-gestures-setup || die
  38 }
  39
  40 pkg_postinst() {
  41         gnome2_icon_cache_update
  42
  43         elog "You must be in the input group to read the touchpad device."
  44
  45         if ! has_version x11-libs/gtk+:3 ; then
  46                 elog "${PN}-setup script supports Gnome 3 via x11-libs/gtk+:3."
  47         fi
  48         if ! has_version kde-plasma/kde-cli-tools:5 ; then
  49                 elog "${PN}-setup script supports Plasma 5 via kde-plasma/kde-cli-tools:5."
  50         fi
  51 }
  52
  53 pkg_postrm() {
  54         gnome2_icon_cache_update
  55 }