x11-misc/kdocker/kdocker-5.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit bash-completion-r1 qmake-utils xdg
   7
   8 MY_P=KDocker-${PV}
   9 DESCRIPTION="Helper to dock any application into the system tray"
  10 HOMEPAGE="https://github.com/user-none/KDocker"
  11 SRC_URI="https://github.com/user-none/KDocker/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE=""
  17
  18 DEPEND="
  19         dev-qt/qtcore:5
  20         dev-qt/qtgui:5
  21         dev-qt/qtsingleapplication[qt5(+),X]
  22         dev-qt/qtwidgets:5
  23         dev-qt/qtx11extras:5
  24         x11-libs/libX11
  25         x11-libs/libXmu
  26         x11-libs/libXpm
  27 "
  28 RDEPEND="${DEPEND}"
  29
  30 DOCS=( AUTHORS BUGS ChangeLog CREDITS README.md TODO )
  31
  32 PATCHES=(
  33         "${FILESDIR}"/qt-5.14.patch
  34 )
  35
  36 S=${WORKDIR}/${MY_P}
  37
  38 src_prepare() {
  39         default
  40
  41         sed -i -e "/completion.path/s%/etc/bash_completion.d%$(get_bashcompdir)%" \
  42                 kdocker.pro || die "sed failed"
  43 }
  44
  45 src_configure() {
  46         eqmake5 PREFIX="${EPREFIX}/usr" SYSTEMQTSA=1
  47 }
  48
  49 src_install() {
  50         emake INSTALL_ROOT="${D}" install
  51         einstalldocs
  52 }