x11-misc/kapow/kapow-1.5.9.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit qmake-utils xdg-utils
   6
   7 DESCRIPTION="A punch clock program designed to easily keep track of your hours"
   8 HOMEPAGE="https://gottcode.org/kapow/"
   9 SRC_URI="https://gottcode.org/${PN}/${P}-src.tar.bz2"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14
  15 RDEPEND="
  16         dev-qt/qtcore:5
  17         dev-qt/qtgui:5
  18         dev-qt/qtnetwork:5
  19         dev-qt/qtprintsupport:5
  20         dev-qt/qtwidgets:5
  21 "
  22 DEPEND="
  23         ${RDEPEND}
  24         dev-qt/linguist-tools:5
  25 "
  26 K_LANGS="
  27         ar bg cs da de el en es fr it lt nl no pl pt_BR pt ro ru sv tr uk
  28 "
  29 for K_LANG in ${K_LANGS}; do
  30         IUSE+=" l10n_${K_LANG/_/-}"
  31 done
  32 DOCS=( ChangeLog README )
  33
  34 src_prepare() {
  35         default
  36
  37         count() { echo ${#}; }
  38         local lang_count=$(count ${K_LANGS})
  39         local locale_count=$(count translations/${PN}_*.ts)
  40         [[ ${lang_count} = ${locale_count} ]] \
  41                 || die "Number of LANGS does not match number of locales"
  42         unset count
  43
  44         local lang
  45         for lang in ${K_LANGS}; do
  46                 if ! use l10n_${lang/_/-}; then
  47                         rm translations/${PN}_${lang}.* || die
  48                 fi
  49         done
  50 }
  51
  52 src_configure() {
  53         eqmake5 kapow.pro PREFIX=/usr
  54 }
  55
  56 src_install() {
  57         export INSTALL_ROOT="${D}"
  58         default
  59 }
  60
  61 pkg_postinst() {
  62         xdg_icon_cache_update
  63 }
  64
  65 pkg_postrm() {
  66         xdg_icon_cache_update
  67 }