x11-misc/fraqtive/fraqtive-0.4.8-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit qmake-utils toolchain-funcs xdg
   7
   8 DESCRIPTION="Open source, multi-platform generator of the Mandelbrot family fractals"
   9 HOMEPAGE="https://fraqtive.mimec.org/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="cpu_flags_x86_sse2"
  16
  17 BDEPEND="
  18         virtual/pkgconfig
  19 "
  20 DEPEND="
  21         dev-qt/qtcore:5
  22         dev-qt/qtgui:5
  23         dev-qt/qtopengl:5
  24         virtual/glu
  25 "
  26 RDEPEND="${DEPEND}"
  27
  28 PATCHES=( "${FILESDIR}/${P}-qt-includes.patch" )
  29
  30 src_configure() {
  31         tc-export PKG_CONFIG
  32         sed -i -e "s|-lGLU|$( ${PKG_CONFIG} --libs glu )|g" src/src.pro || die
  33         local conf="release"
  34
  35         if use cpu_flags_x86_sse2; then
  36                 conf="$conf sse2"
  37         else
  38                 conf="$conf no-sse2"
  39         fi
  40
  41         echo "CONFIG += $conf" > config.pri
  42         echo "PREFIX = ${EPREFIX}/usr" >> config.pri
  43         # Don't strip wrt #252096
  44         echo "QMAKE_STRIP =" >> config.pri
  45
  46         eqmake5
  47 }
  48
  49 src_install() {
  50         emake INSTALL_ROOT="${D}" install
  51 }