x11-misc/devilspie/devilspie-0.23.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools toolchain-funcs
   6
   7 DESCRIPTION="A Window Matching utility similar to Sawfish's Matched Windows feature"
   8 HOMEPAGE="http://www.burtonini.com/blog/tag/devilspie.html"
   9 SRC_URI="http://www.burtonini.com/computing/${P}.tar.xz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 ppc sparc x86 ~amd64-linux ~x86-linux"
  14 IUSE=""
  15
  16 RDEPEND="
  17         >=dev-libs/glib-2.10
  18         x11-libs/gtk+:3[X]
  19         x11-libs/libwnck:3
  20         x11-libs/libX11"
  21 DEPEND="${RDEPEND}
  22         virtual/pkgconfig
  23         dev-util/intltool
  24         sys-devel/gettext
  25         gnome-base/gnome-common" # Required by eautoreconf
  26
  27 src_prepare() {
  28         default
  29         sed -i -e "s:\(/usr/share/doc/devilspie\):\1-${PVR}:" devilspie.1 || die
  30         sed -i -e '/-DG.*_DISABLE_DEPRECATED/d' src/Makefile.am || die
  31         mv configure.{in,ac} || die
  32         eautoreconf
  33         LIBS="$($(tc-getPKG_CONFIG) --libs x11)"
  34 }
  35
  36 src_install() {
  37         default
  38         keepdir /etc/devilspie
  39 }