x11-misc/dclock/dclock-2.2.2_p9.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit flag-o-matic toolchain-funcs
   6
   7 DESCRIPTION="Digital clock for the X window system"
   8 HOMEPAGE="https://packages.qa.debian.org/d/dclock.html"
   9 SRC_URI="
  10         mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p*/}.orig.tar.gz
  11         mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p/-}.debian.tar.xz
  12 "
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc x86"
  17 IUSE="xft"
  18
  19 RDEPEND="
  20         xft? (
  21                 media-libs/freetype
  22                 x11-libs/libXft
  23         )
  24         x11-libs/libX11
  25         x11-libs/libXext
  26         x11-libs/libXt
  27 "
  28 DEPEND="
  29         ${RDEPEND}
  30         app-text/rman
  31         x11-misc/imake
  32         xft? ( virtual/pkgconfig )
  33 "
  34
  35 S=${WORKDIR}/${P/_p*/}
  36
  37 PATCHES=(
  38         "${WORKDIR}"/debian/patches
  39         "${FILESDIR}"/${PN}-2.2.2_p4-include.patch
  40 )
  41
  42 src_configure() {
  43         if use xft; then
  44                 append-cppflags \
  45                         -DXFT_SUPPORT \
  46                         $( $(tc-getPKG_CONFIG) --cflags freetype2)
  47         else
  48                 append-cppflags -UXFT_SUPPORT
  49                 sed -i -e '/EXTRA_LIBRARIES/s|^|#|g' Imakefile || die
  50         fi
  51
  52         xmkmf || die
  53 }
  54
  55 src_compile() {
  56         emake \
  57                 CC="$(tc-getCC)" \
  58                 CFLAGS="${CFLAGS}" \
  59                 CPPFLAGS="${CPPFLAGS}" \
  60                 EXTRA_LDOPTIONS="${LDFLAGS}"
  61 }
  62
  63 src_install() {
  64         default
  65         emake DESTDIR="${D}" install.man
  66
  67         insinto /usr/share/sounds
  68         doins sounds/*
  69
  70         insinto /usr/share/X11/app-defaults
  71         newins Dclock.ad DClock
  72 }