x11-misc/bumblebee/bumblebee-3.2.1_p20170130.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools multilib readme.gentoo-r1 systemd user
   7
   8 if [[ ${PV} == 9999 ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/Bumblebee-Project/Bumblebee.git"
  11         EGIT_BRANCH="develop"
  12         KEYWORDS=""
  13 else
  14         COMMIT="d469a32fc0dfef5b3725c7a5331be2d04b870594"
  15         SRC_URI="https://github.com/Bumblebee-Project/Bumblebee/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
  16         KEYWORDS="~amd64 ~x86"
  17
  18         S="${WORKDIR}/Bumblebee-${COMMIT}"
  19 fi
  20
  21 DESCRIPTION="Service providing elegant and stable means of managing Optimus graphics chipsets"
  22 HOMEPAGE="https://bumblebee-project.org https://github.com/Bumblebee-Project/Bumblebee"
  23
  24 SLOT="0"
  25 LICENSE="GPL-3"
  26
  27 IUSE="+bbswitch video_cards_nouveau video_cards_nvidia"
  28
  29 COMMON_DEPEND="
  30         dev-libs/glib:2
  31         dev-libs/libbsd
  32         sys-apps/kmod
  33         x11-libs/libX11
  34 "
  35
  36 RDEPEND="${COMMON_DEPEND}
  37         virtual/opengl
  38         x11-base/xorg-drivers[video_cards_nvidia?,video_cards_nouveau?]
  39         bbswitch? ( sys-power/bbswitch )
  40 "
  41
  42 DEPEND="${COMMON_DEPEND}
  43         sys-apps/help2man
  44         virtual/pkgconfig
  45 "
  46
  47 PDEPEND="
  48         || (
  49                 x11-misc/primus
  50                 x11-misc/virtualgl
  51         )
  52 "
  53
  54 REQUIRED_USE="|| ( video_cards_nouveau video_cards_nvidia )"
  55
  56 pkg_setup() {
  57         enewgroup bumblebee
  58 }
  59
  60 src_prepare() {
  61         default
  62         eautoreconf
  63 }
  64
  65 src_configure() {
  66         if use video_cards_nvidia ; then
  67                 # Get paths to GL libs for all ABIs
  68                 local i nvlib=""
  69                 for i in  $(get_all_libdirs) ; do
  70                         nvlib="${nvlib}:/usr/${i}/opengl/nvidia/lib"
  71                 done
  72
  73                 local nvpref="/usr/$(get_libdir)/opengl/nvidia"
  74                 local xorgpref="/usr/$(get_libdir)/xorg/modules"
  75                 ECONF_PARAMS="CONF_DRIVER=nvidia CONF_DRIVER_MODULE_NVIDIA=nvidia \
  76                         CONF_LDPATH_NVIDIA=${nvlib#:} \
  77                         CONF_MODPATH_NVIDIA=${nvpref}/lib,${nvpref}/extensions,${xorgpref}/drivers,${xorgpref}"
  78         fi
  79
  80         econf \
  81                 ${ECONF_PARAMS}
  82 }
  83
  84 src_install() {
  85         default
  86
  87         newconfd "${FILESDIR}"/${PN}.confd ${PN}
  88         newinitd "${FILESDIR}"/${PN}.initd ${PN}
  89         newenvd "${FILESDIR}"/${PN}.envd 99${PN}
  90         systemd_dounit scripts/systemd/bumblebeed.service
  91
  92         local DOC_CONTENTS="In order to use Bumblebee, add your user to 'bumblebee' group.
  93                 You may need to setup your /etc/bumblebee/bumblebee.conf"
  94         readme.gentoo_create_doc
  95 }