x11-libs/xbae/xbae-4.60.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Motif-based widget to display a grid of cells as a spreadsheet"
   7 HOMEPAGE="http://xbae.sourceforge.net/"
   8 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
   9
  10 LICENSE="BSD"
  11 SLOT="0"
  12 KEYWORDS="~alpha amd64 hppa ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
  13 IUSE="doc examples"
  14 # tests need X display
  15 # and are interactive so virtualx will not help
  16 RESTRICT="test"
  17
  18 RDEPEND="
  19         x11-libs/motif:0
  20         x11-libs/libXau
  21         x11-libs/libXdmcp
  22         x11-libs/libXext
  23         x11-libs/libXmu
  24         x11-libs/libXpm
  25         x11-libs/libXt"
  26 DEPEND="${RDEPEND}"
  27
  28 PATCHES=(
  29         "${FILESDIR}"/${P}-tmpl.patch
  30         "${FILESDIR}"/${P}-lxmp.patch
  31         "${FILESDIR}"/${P}-Makefile.in.patch
  32 )
  33
  34 src_configure() {
  35         econf --enable-production
  36 }
  37
  38 src_test() {
  39         emake -C examples
  40         emake -C examples/testall clean
  41 }
  42
  43 src_install() {
  44         default
  45
  46         insinto /usr/share/aclocal
  47         doins ac_find_xbae.m4
  48
  49         if use examples; then
  50                 find examples -name '*akefile*' -delete || die
  51                 rm examples/{testall,extest} || die
  52                 dodoc -r examples
  53         fi
  54         if use doc; then
  55                 rm doc/{,images/}Makefile* || die
  56                 docinto html
  57                 dodoc -r doc/.
  58         fi
  59
  60         # no static archives
  61         find "${D}" -name '*.la' -delete || die
  62 }