x11-libs/vte/vte-0.56.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 VALA_USE_DEPEND="vapigen"
   6 VALA_MIN_API_VERSION="0.32"
   7
   8 inherit gnome2 vala
   9
  10 DESCRIPTION="Library providing a virtual terminal emulator widget"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"
  12
  13 LICENSE="LGPL-2+"
  14 SLOT="2.91"
  15 IUSE="+crypt debug glade +introspection +vala vanilla"
  16 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
  17 REQUIRED_USE="vala? ( introspection )"
  18
  19 SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~leio/distfiles/${PN}-0.54.1-command-notify.patch.xz )"
  20
  21 RDEPEND="
  22         >=dev-libs/glib-2.40:2
  23         >=dev-libs/libpcre2-10.21
  24         >=x11-libs/gtk+-3.16:3[introspection?]
  25         >=x11-libs/pango-1.22.0
  26
  27         sys-libs/ncurses:0=
  28         sys-libs/zlib
  29
  30         crypt?  ( >=net-libs/gnutls-3.2.7:0= )
  31         glade? ( >=dev-util/glade-3.9:3.10 )
  32         introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
  33 "
  34 DEPEND="${RDEPEND}
  35         dev-libs/libxml2:2
  36         dev-util/glib-utils
  37         >=dev-util/gtk-doc-am-1.13
  38         >=dev-util/intltool-0.35
  39         sys-devel/gettext
  40         virtual/pkgconfig
  41
  42         vala? ( $(vala_depend) )
  43 "
  44 RDEPEND="${RDEPEND}
  45         !x11-libs/vte:2.90[glade]
  46 "
  47
  48 src_prepare() {
  49         if ! use vanilla; then
  50                 # Part of https://src.fedoraproject.org/rpms/vte291/blob/f30/f/vte291-cntr-ntfy-scroll.patch
  51                 # Patch distfile for 0.54 series is re-used, as only git hashes and co changed in patchset.
  52                 # Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
  53                 eapply "${WORKDIR}"/${PN}-0.54.1-command-notify.patch
  54         fi
  55
  56         use vala && vala_src_prepare
  57
  58         # build fails because of -Werror with gcc-5.x
  59         sed -e 's#-Werror=format=2#-Wformat=2#' -i configure || die "sed failed"
  60
  61         gnome2_src_prepare
  62 }
  63
  64 src_configure() {
  65         local myconf=""
  66
  67         if [[ ${CHOST} == *-interix* ]]; then
  68                 myconf="${myconf} --disable-Bsymbolic"
  69
  70                 # interix stropts.h is empty...
  71                 export ac_cv_header_stropts_h=no
  72         fi
  73
  74         gnome2_src_configure \
  75                 --disable-static \
  76                 --with-gtk=3.0 \
  77                 --with-iconv \
  78                 $(use_enable debug) \
  79                 $(use_enable glade glade-catalogue) \
  80                 $(use_with crypt gnutls) \
  81                 $(use_enable introspection) \
  82                 $(use_enable vala) \
  83                 ${myconf}
  84 }
  85
  86 src_install() {
  87         gnome2_src_install
  88         mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
  89 }