x11-libs/pango/pango-1.42.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6
   7 inherit gnome2 multilib-minimal toolchain-funcs
   8
   9 DESCRIPTION="Internationalized text layout and rendering library"
  10 HOMEPAGE="http://www.pango.org/"
  11
  12 LICENSE="LGPL-2+ FTL"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  15
  16 IUSE="X +introspection test"
  17
  18 RDEPEND="
  19         >=media-libs/harfbuzz-1.4.2:=[glib(+),truetype(+),${MULTILIB_USEDEP}]
  20         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  21         >=media-libs/fontconfig-2.12.92:1.0=[${MULTILIB_USEDEP}]
  22         >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}]
  23         >=x11-libs/cairo-1.12.14-r4:=[X?,${MULTILIB_USEDEP}]
  24         >=dev-libs/fribidi-0.19.7[${MULTILIB_USEDEP}]
  25         introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
  26         X? (
  27                 >=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
  28                 >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  29                 >=x11-libs/libXft-2.3.1-r1[${MULTILIB_USEDEP}]
  30         )
  31 "
  32 DEPEND="${RDEPEND}
  33         >=dev-util/gtk-doc-am-1.20
  34         virtual/pkgconfig[${MULTILIB_USEDEP}]
  35         test? ( media-fonts/cantarell )
  36         X? ( x11-base/xorg-proto )
  37         !<=sys-devel/autoconf-2.63:2.5
  38 "
  39
  40 src_prepare() {
  41         default
  42         # This should be updated if next release fails to pre-generate the manpage as well, or src_prepare removed if is properly generated
  43         # https://gitlab.gnome.org/GNOME/pango/issues/270
  44         cp -v "${FILESDIR}"/${PV}-pango-view.1.in "${S}/utils/pango-view.1.in" || die
  45 }
  46
  47 multilib_src_configure() {
  48         tc-export CXX
  49
  50         ECONF_SOURCE=${S} \
  51         gnome2_src_configure \
  52                 --with-cairo \
  53                 $(multilib_native_use_enable introspection) \
  54                 $(use_with X xft) \
  55                 "$(usex X --x-includes="${EPREFIX}/usr/include" "")" \
  56                 "$(usex X --x-libraries="${EPREFIX}/usr/$(get_libdir)" "")"
  57
  58         if multilib_is_native_abi; then
  59                 ln -s "${S}"/docs/html docs/html || die
  60         fi
  61 }
  62
  63 multilib_src_install() {
  64         gnome2_src_install
  65 }