x11-libs/mx/mx-1.4.7-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 GCONF_DEBUG="yes"
   6
   7 inherit gnome2 eutils
   8
   9 DESCRIPTION="A widget toolkit using Clutter"
  10 HOMEPAGE="http://clutter-project.org/"
  11 SRC_URI="https://github.com/downloads/clutter-project/${PN}/${P}.tar.xz"
  12
  13 LICENSE="LGPL-2.1"
  14 SLOT="1.0"
  15 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
  16 IUSE="dbus +gtk +introspection startup-notification"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.28.0:2
  20         >=media-libs/clutter-1.7.91:1.0
  21         media-libs/cogl:=
  22         >=x11-apps/xrandr-1.2.0
  23
  24         x11-libs/gdk-pixbuf:2[introspection?]
  25
  26         dbus? ( >=dev-libs/dbus-glib-0.82 )
  27         gtk? ( >=x11-libs/gtk+-2.20:2[introspection?] )
  28         introspection? ( >=dev-libs/gobject-introspection-0.6.4:= )
  29         startup-notification? ( >=x11-libs/startup-notification-0.9 )
  30 "
  31 DEPEND="${RDEPEND}
  32         dev-util/glib-utils
  33         >=dev-util/gtk-doc-am-1.14
  34         >=dev-util/intltool-0.35.0
  35         sys-devel/gettext
  36         virtual/pkgconfig
  37 "
  38
  39 src_prepare() {
  40         # Tests are interactive, no use for us
  41         sed -e 's/^\(SUBDIRS .*\)tests\(.*\)/\1 \2/g' \
  42                 -i Makefile.am -i Makefile.in || die
  43         # In 1.4.8
  44         epatch "${FILESDIR}/${P}-gl-types.patch"
  45
  46         gnome2_src_prepare
  47 }
  48
  49 src_configure() {
  50         gnome2_src_configure \
  51                 --with-winsys=x11 \
  52                 --without-glade \
  53                 $(use_enable gtk gtk-widgets) \
  54                 $(use_enable introspection) \
  55                 $(use_with dbus) \
  56                 $(use_with startup-notification)
  57 }