x11-libs/motif/motif-2.2.3-r12.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools eutils flag-o-matic multilib multilib-minimal
   7
   8 MY_P=openMotif-${PV}
   9 DESCRIPTION="Legacy Open Motif libraries for old binaries"
  10 HOMEPAGE="http://motif.ics.com/"
  11 SRC_URI="ftp://ftp.ics.com/openmotif/2.2/${PV}/src/${MY_P}.tar.gz
  12         mirror://gentoo/openmotif-${PV}-patches-5.tar.xz"
  13
  14 LICENSE="MOTIF MIT"
  15 SLOT="2.2"
  16 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
  17
  18 RDEPEND=">=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  19         >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
  20         >=x11-libs/libXmu-1.1.1-r1[${MULTILIB_USEDEP}]
  21         >=x11-libs/libXp-1.0.2[${MULTILIB_USEDEP}]
  22         >=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]"
  23
  24 DEPEND="${RDEPEND}
  25         x11-libs/libXaw
  26         x11-misc/xbitmaps"
  27
  28 S="${WORKDIR}/${MY_P}"
  29
  30 src_prepare() {
  31         EPATCH_SUFFIX=patch epatch
  32         epatch_user
  33
  34         # This replaces deprecated, obsoleted and now invalid AC_DEFINE
  35         # with their proper alternatives.
  36         sed -i -e 's:AC_DEFINE(\([^)]*\)):AC_DEFINE(\1, [], [\1]):g' \
  37                 configure.in acinclude.m4
  38
  39         # Build only the libraries
  40         sed -i -e '/^SUBDIRS/{:x;/\\$/{N;bx;};s/=.*/= lib clients/;}' Makefile.am
  41         sed -i -e '/^SUBDIRS/{:x;/\\$/{N;bx;};s/=.*/= uil/;}' clients/Makefile.am
  42
  43         mv configure.in configure.ac || die
  44         AM_OPTS="--force-missing" eautoreconf
  45
  46         # get around some LANG problems in make (#15119)
  47         unset LANG
  48
  49         # bug #80421
  50         filter-flags -ftracer
  51
  52         # feel free to fix properly if you care
  53         append-flags -fno-strict-aliasing
  54 }
  55
  56 multilib_src_configure() {
  57         ECONF_SOURCE="${S}" econf --with-x --disable-static
  58 }
  59
  60 multilib_src_compile() {
  61         emake -j1
  62 }
  63
  64 multilib_src_install() {
  65         emake -j1 DESTDIR="${D}" install-exec
  66 }
  67
  68 multilib_src_install_all() {
  69         # cleanups
  70         rm -rf "${ED}"/usr/bin
  71         rm -f "${ED}"/usr/lib*/*.{so,la,a}
  72
  73         dodoc README RELEASE RELNOTES BUGREPORT TODO
  74 }