x11-libs/gtksourceview/gtksourceview-3.24.8.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 VALA_MIN_API_VERSION="0.24"
   6 VALA_USE_DEPEND="vapigen"
   7
   8 inherit gnome2 vala virtualx
   9
  10 DESCRIPTION="A text widget implementing syntax highlighting and other features"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
  12
  13 LICENSE="GPL-2+ LGPL-2.1+"
  14 SLOT="3.0/3"
  15
  16 IUSE="glade +introspection vala"
  17 REQUIRED_USE="vala? ( introspection )"
  18
  19 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
  20
  21 RDEPEND="
  22         >=dev-libs/glib-2.48:2
  23         >=dev-libs/libxml2-2.6:2
  24         >=x11-libs/gtk+-3.20:3[introspection?]
  25         glade? ( >=dev-util/glade-3.9:3.10 )
  26         introspection? ( >=dev-libs/gobject-introspection-1.42:= )
  27 "
  28 DEPEND="${RDEPEND}
  29         >=dev-util/gtk-doc-am-1.25
  30         >=sys-devel/gettext-0.19.4
  31         dev-util/itstool
  32         virtual/pkgconfig
  33         vala? ( $(vala_depend) )
  34 "
  35
  36 src_prepare() {
  37         use vala && vala_src_prepare
  38         gnome2_src_prepare
  39 }
  40
  41 src_configure() {
  42         gnome2_src_configure \
  43                 --disable-deprecations \
  44                 $(use_enable glade glade-catalog) \
  45                 $(use_enable introspection) \
  46                 $(use_enable vala)
  47 }
  48
  49 src_test() {
  50         virtx emake check
  51 }
  52
  53 src_install() {
  54         gnome2_src_install
  55
  56         insinto /usr/share/${PN}-3.0/language-specs
  57         doins "${FILESDIR}"/2.0/gentoo.lang
  58 }