x11-libs/goocanvas/goocanvas-1.0.0.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG=no
   7 GNOME2_LA_PUNT=yes
   8 GNOME_TARBALL_SUFFIX="bz2"
   9
  10 inherit eutils gnome2 libtool
  11
  12 DESCRIPTION="Canvas widget for GTK+ using the cairo 2D library for drawing"
  13 HOMEPAGE="https://wiki.gnome.org/Projects/GooCanvas"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 ia64 ppc ppc64 sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux"
  18 IUSE="examples"
  19
  20 RDEPEND="
  21         >=x11-libs/gtk+-2.12:2
  22         >=dev-libs/glib-2.10:2
  23         >=x11-libs/cairo-1.4
  24 "
  25 DEPEND="${RDEPEND}
  26         dev-util/gtk-doc-am
  27         virtual/pkgconfig
  28 "
  29
  30 src_prepare() {
  31         # https://bugzilla.gnome.org/show_bug.cgi?id=671766
  32         epatch "${FILESDIR}"/${P}-gold.patch
  33
  34         # Fails to build with recent GTK+
  35         sed -e "s/-D.*_DISABLE_DEPRECATED//g" \
  36                 -i src/Makefile.am src/Makefile.in demo/Makefile.am demo/Makefile.in \
  37                 || die "sed 1 failed"
  38
  39         sed -e 's/^\(SUBDIRS =.*\)demo\(.*\)$/\1\2/' \
  40                 -i Makefile.am Makefile.in || die "sed 2 failed"
  41
  42         gnome2_src_prepare
  43 }
  44
  45 src_configure() {
  46         gnome2_src_configure \
  47                 --disable-rebuilds \
  48                 --disable-static
  49 }
  50
  51 src_install() {
  52         gnome2_src_install
  53
  54         if use examples; then
  55                 insinto /usr/share/doc/${P}/examples/
  56                 doins demo/*.c demo/flower.png demo/toroid.png
  57         fi
  58 }