www-servers/puma/puma-3.12.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 USE_RUBY="ruby24 ruby25 ruby26"
   7
   8 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
   9
  10 inherit multilib ruby-fakegem
  11
  12 DESCRIPTION="a simple, fast, threaded, and highly concurrent HTTP 1.1 server for Ruby/Rack"
  13 HOMEPAGE="https://puma.io/"
  14 SRC_URI="https://github.com/puma/puma/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  15
  16 LICENSE="BSD"
  17 SLOT="3"
  18 KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 x86"
  19 IUSE=""
  20
  21 DEPEND+=" dev-libs/openssl:0 test? ( net-misc/curl )"
  22 RDEPEND+=" dev-libs/openssl:0"
  23
  24 ruby_add_bdepend "virtual/ruby-ssl
  25         test? ( dev-ruby/rack >=dev-ruby/minitest-5.9:5 >=dev-ruby/test-unit-3.0:2 )"
  26
  27 all_ruby_prepare() {
  28         eapply "${FILESDIR}/${PN}-3.12.1-ruby26-waitpid.patch"
  29
  30         sed -i -e '/bundler/ s:^:#:' test/helper.rb || die
  31
  32         # Avoid test failing inconsistently
  33         sed -i -e '/phased_restart_via_pumactl/,/^  end/ s:^:#:' test/test_integration.rb || die
  34
  35         # Avoid test that trigger a bug in ruby very easily and lead to
  36         # failure. This affects all current puma versions in combination
  37         # with the latest ruby versions, so we add this new version anyway
  38         # while allowing these tests to fail.
  39         # https://github.com/puma/puma/pull/1345
  40         rm -f test/test_puma_server_ssl.rb || die
  41
  42         # Use correct ruby version
  43         sed -i -e 's/ruby -rrubygems/#{Gem.ruby} -rrubygems/' test/shell/t{1,3}.rb || die
  44 }
  45
  46 each_ruby_prepare() {
  47         sed -i -e 's:ruby -rubygems:'${RUBY}' -rubygems:' \
  48                 -e 's/localhost/127.0.0.1/' test/shell/* || die
  49         sed -i -e '1ilog_requests' test/shell/t{1,2}_conf.rb || die
  50 }
  51
  52 each_ruby_configure() {
  53         ${RUBY} -Cext/puma_http11 extconf.rb || die
  54 }
  55
  56 each_ruby_compile() {
  57         emake V=1 -Cext/puma_http11
  58         cp ext/puma_http11/puma_http11$(get_modname) lib/puma/ || die
  59 }
  60
  61 each_ruby_test() {
  62         einfo "Running test suite"
  63         ${RUBY} -Ilib:.:test -e "gem 'minitest', '~>5.9'; gem 'test-unit', '~>3.0'; require 'minitest/autorun'; Dir['test/**/*test_*.rb'].each{|f| require f}" || die
  64
  65         einfo "Running integration tests"
  66         pushd test/shell
  67         #sh run.sh || die
  68         popd
  69 }