www-plugins/chrome-binary-plugins/chrome-binary-plugins-73.0.3683.56_beta.ebuild

   1 # Copyright 2012-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit multilib unpacker
   7
   8 DESCRIPTION="Binary plugins from Google Chrome for use in Chromium"
   9 HOMEPAGE="https://www.google.com/chrome"
  10
  11 case ${PV} in
  12         *_alpha*)
  13                 SLOT="unstable"
  14                 CHROMEDIR="opt/google/chrome-${SLOT}"
  15                 MY_PV=${PV%_alpha}-1
  16                 ;;
  17         *_beta*)
  18                 SLOT="beta"
  19                 CHROMEDIR="opt/google/chrome-${SLOT}"
  20                 MY_PV=${PV%_beta}-1
  21                 ;;
  22         *)
  23                 SLOT="stable"
  24                 CHROMEDIR="opt/google/chrome"
  25                 MY_PV=${PV}-1
  26                 ;;
  27 esac
  28
  29 MY_PN="google-chrome-${SLOT}"
  30 MY_P="${MY_PN}_${MY_PV}"
  31
  32 SRC_URI="https://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb"
  33 KEYWORDS="-* ~amd64"
  34
  35 LICENSE="google-chrome"
  36 IUSE="+widevine"
  37 RESTRICT="bindist mirror strip"
  38
  39 RDEPEND="
  40         widevine? (
  41                 dev-libs/glib:2
  42                 dev-libs/nspr
  43                 dev-libs/nss
  44                 !<www-client/chromium-57[widevine(-)]
  45         )
  46 "
  47
  48 for x in 0 beta stable unstable; do
  49         if [[ ${SLOT} != ${x} ]]; then
  50                 RDEPEND+=" !${CATEGORY}/${PN}:${x}"
  51         fi
  52 done
  53
  54 S="${WORKDIR}/${CHROMEDIR}"
  55 QA_PREBUILT="*"
  56
  57 pkg_nofetch() {
  58         eerror "Please wait 24 hours and sync your portage tree before reporting fetch failures."
  59 }
  60
  61 src_install() {
  62         insinto /usr/$(get_libdir)/chromium
  63         if use widevine; then
  64                 doins libwidevinecdm.so
  65                 dosym ../chromium/libwidevinecdm.so /usr/$(get_libdir)/chromium-browser/libwidevinecdm.so
  66         fi
  67 }