www-client/vivaldi-snapshot/vivaldi-snapshot-3.0.1874.5_p1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 CHROMIUM_LANGS="
   6         af am ar be bg bn ca cs da de de-CH el en-GB en-US eo es es-419 es-PE et eu
   7         fa fi fil fr fy gd gl gu he hi hr hu hy id io is it ja jbo ka kn ko ku lt
   8         lv mk ml mr ms nb nl nn pl pt-BR pt-PT ro ru sc sk sl sq sr sv sw ta te th
   9         tr uk vi zh-CN zh-TW
  10 "
  11 inherit chromium-2 multilib unpacker toolchain-funcs xdg-utils
  12
  13 VIVALDI_HOME="opt/${PN}"
  14 DESCRIPTION="A browser for our friends"
  15 HOMEPAGE="https://vivaldi.com/"
  16 VIVALDI_BASE_URI="https://downloads.vivaldi.com/snapshot/${PN}_${PV/_p/-}_"
  17 SRC_URI="
  18         amd64? ( ${VIVALDI_BASE_URI}amd64.deb -> ${P}-amd64.deb )
  19         arm64? ( ${VIVALDI_BASE_URI}arm64.deb -> ${P}-arm64.deb )
  20         arm? ( ${VIVALDI_BASE_URI}armhf.deb -> ${P}-armhf.deb )
  21         x86? ( ${VIVALDI_BASE_URI}i386.deb -> ${P}-i386.deb )
  22 "
  23
  24 LICENSE="Vivaldi"
  25 SLOT="0"
  26 KEYWORDS="-* ~amd64 ~arm ~arm64 ~x86"
  27 RESTRICT="bindist mirror"
  28
  29 DEPEND="
  30         virtual/libiconv
  31 "
  32 RDEPEND="
  33         dev-libs/expat
  34         dev-libs/glib:2
  35         dev-libs/nspr
  36         dev-libs/nss
  37         media-libs/alsa-lib
  38         media-libs/fontconfig
  39         media-libs/freetype
  40         media-libs/speex
  41         net-print/cups
  42         sys-apps/dbus
  43         sys-libs/libcap
  44         x11-libs/cairo
  45         x11-libs/gdk-pixbuf
  46         x11-libs/gtk+:3
  47         x11-libs/libX11
  48         x11-libs/libXScrnSaver
  49         x11-libs/libXcomposite
  50         x11-libs/libXcursor
  51         x11-libs/libXdamage
  52         x11-libs/libXext
  53         x11-libs/libXfixes
  54         x11-libs/libXi
  55         x11-libs/libXrandr
  56         x11-libs/libXrender
  57         x11-libs/libXtst
  58         x11-libs/pango[X]
  59 "
  60 QA_PREBUILT="*"
  61 S=${WORKDIR}
  62
  63 src_unpack() {
  64         unpack_deb ${A}
  65 }
  66
  67 src_prepare() {
  68         iconv -c -t UTF-8 usr/share/applications/${PN}.desktop > "${T}"/${PN}.desktop || die
  69         mv "${T}"/${PN}.desktop usr/share/applications/${PN}.desktop || die
  70
  71         mv usr/share/doc/${PN} usr/share/doc/${PF} || die
  72         chmod 0755 usr/share/doc/${PF} || die
  73
  74         gunzip usr/share/doc/${PF}/changelog.gz || die
  75
  76         rm \
  77                 _gpgbuilder \
  78                 etc/cron.daily/${PN} \
  79                 || die
  80         rmdir \
  81                 etc/cron.daily/ \
  82                 etc/ \
  83                 || die
  84
  85         local c d
  86         for d in 16 22 24 32 48 64 128 256; do
  87                 mkdir -p usr/share/icons/hicolor/${d}x${d}/apps || die
  88                 cp \
  89                         ${VIVALDI_HOME}/product_logo_${d}.png \
  90                         usr/share/icons/hicolor/${d}x${d}/apps/${PN}.png || die
  91         done
  92
  93         pushd "${VIVALDI_HOME}/locales" > /dev/null || die
  94         chromium_remove_language_paks
  95         popd > /dev/null || die
  96
  97         eapply_user
  98 }
  99
 100 src_install() {
 101         rm -r usr/share/appdata || die
 102         mv * "${D}" || die
 103         dosym /${VIVALDI_HOME}/${PN} /usr/bin/${PN}
 104
 105         fperms 4711 /${VIVALDI_HOME}/vivaldi-sandbox
 106 }
 107
 108 pkg_postrm() {
 109         xdg_desktop_database_update
 110         xdg_icon_cache_update
 111 }
 112
 113 pkg_postinst() {
 114         xdg_desktop_database_update
 115         xdg_icon_cache_update
 116 }