www-client/opera-beta/opera-beta-36.0.2130.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 CHROMIUM_LANGS="
   7         af az be bg bn ca cs da de el en_GB en_US es_419 es fil fi fr_CA fr fy gd
   8         he hi hr hu id it ja kk ko lt lv me mk ms nb nl nn pa pl pt_BR pt_PT ro ru
   9         sk sr sv sw ta te th tr uk uz vi zh_CN zh_TW zu
  10 "
  11 inherit chromium multilib unpacker
  12
  13 DESCRIPTION="A fast and secure web browser"
  14 HOMEPAGE="http://www.opera.com/"
  15 LICENSE="OPERA-2014"
  16 SLOT="0"
  17 SRC_URI_BASE="http://get.geo.opera.com/pub/"
  18 SRC_URI="
  19         amd64? ( "${SRC_URI_BASE}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb" )
  20 "
  21 KEYWORDS="~amd64"
  22
  23 RDEPEND="
  24         dev-libs/expat
  25         dev-libs/glib:2
  26         dev-libs/nspr
  27         dev-libs/nss
  28         >=dev-libs/openssl-1.0.1:0
  29         gnome-base/gconf:2
  30         media-libs/alsa-lib
  31         media-libs/fontconfig
  32         media-libs/freetype
  33         net-misc/curl
  34         net-print/cups
  35         sys-apps/dbus
  36         sys-libs/libcap
  37         x11-libs/cairo
  38         x11-libs/gdk-pixbuf
  39         x11-libs/gtk+:2
  40         x11-libs/libX11
  41         x11-libs/libXScrnSaver
  42         x11-libs/libXcomposite
  43         x11-libs/libXcursor
  44         x11-libs/libXdamage
  45         x11-libs/libXext
  46         x11-libs/libXfixes
  47         x11-libs/libXi
  48         x11-libs/libXrandr
  49         x11-libs/libXrender
  50         x11-libs/libXtst
  51         x11-libs/libnotify
  52         x11-libs/pango[X]
  53 "
  54
  55 QA_PREBUILT="*"
  56 S=${WORKDIR}
  57 OPERA_HOME="usr/$(get_libdir)/${PN}"
  58
  59 src_unpack() {
  60         unpack_deb ${A}
  61 }
  62
  63 src_prepare() {
  64         mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
  65         rm -r usr/lib || die
  66
  67         rm usr/bin/${PN} || die
  68
  69         rm usr/share/doc/${PN}/copyright || die
  70         mv usr/share/doc/${PN} usr/share/doc/${PF} || die
  71
  72         pushd "${OPERA_HOME}/localization" > /dev/null || die
  73         chromium_remove_language_paks
  74         popd > /dev/null || die
  75
  76         sed -i \
  77                 -e 's|^TargetEnvironment|X-&|g' \
  78                 usr/share/applications/${PN}.desktop || die
  79 }
  80
  81 src_install() {
  82         mv * "${D}" || die
  83         dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
  84         fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
  85 }