www-client/epiphany/epiphany-3.18.4.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="yes"
   7 GNOME2_LA_PUNT="yes"
   8
   9 inherit eutils gnome2 virtualx
  10
  11 DESCRIPTION="GNOME webbrowser based on Webkit"
  12 HOMEPAGE="https://wiki.gnome.org/Apps/Web"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 IUSE="nss test"
  17 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
  18
  19 COMMON_DEPEND="
  20         >=app-crypt/gcr-3.5.5
  21         >=app-crypt/libsecret-0.14
  22         >=app-text/iso-codes-0.35
  23         >=dev-libs/glib-2.38:2[dbus]
  24         >=dev-libs/libxml2-2.6.12:2
  25         >=dev-libs/libxslt-1.1.7
  26         >=gnome-base/gsettings-desktop-schemas-0.0.1
  27         >=net-dns/avahi-0.6.22[dbus]
  28         >=net-libs/webkit-gtk-2.9.5:4
  29         >=net-libs/libsoup-2.48:2.4
  30         >=x11-libs/gtk+-3.13:3
  31         >=x11-libs/libnotify-0.5.1:=
  32         gnome-base/gnome-desktop:3=
  33
  34         dev-db/sqlite:3
  35         x11-libs/libwnck:3
  36         x11-libs/libX11
  37
  38         nss? ( dev-libs/nss )
  39 "
  40 # epiphany-extensions support was removed in 3.7; let's not pretend it still works
  41 RDEPEND="${COMMON_DEPEND}
  42         x11-themes/adwaita-icon-theme
  43         !www-client/epiphany-extensions
  44 "
  45 # paxctl needed for bug #407085
  46 # eautoreconf requires gnome-common-3.5.5
  47 DEPEND="${COMMON_DEPEND}
  48         app-text/yelp-tools
  49         dev-libs/appstream-glib
  50         >=dev-util/intltool-0.50
  51         dev-util/itstool
  52         sys-apps/paxctl
  53         sys-devel/gettext
  54         virtual/pkgconfig
  55 "
  56
  57 src_prepare() {
  58         # Fix unittests
  59         # https://bugzilla.gnome.org/show_bug.cgi?id=751591
  60         epatch "${FILESDIR}"/${PN}-3.16.0-unittest-1.patch
  61
  62         # https://bugzilla.gnome.org/show_bug.cgi?id=751593
  63         epatch "${FILESDIR}"/${PN}-3.14.0-unittest-2.patch
  64
  65         gnome2_src_prepare
  66 }
  67
  68 src_configure() {
  69         gnome2_src_configure \
  70                 --enable-shared \
  71                 --disable-static \
  72                 --with-distributor-name=Gentoo \
  73                 $(use_enable nss) \
  74                 $(use_enable test tests)
  75 }
  76
  77 src_compile() {
  78         # needed to avoid "Command line `dbus-launch ...' exited with non-zero exit status 1"
  79         unset DISPLAY
  80         gnome2_src_compile
  81 }
  82
  83 src_test() {
  84         "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
  85
  86         unset DISPLAY
  87         GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
  88 }