www-apps/postfixadmin/postfixadmin-3.0.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit user webapp
   7
   8 DESCRIPTION="Web Based Management tool for Postfix style virtual domains and users"
   9 HOMEPAGE="http://postfixadmin.sourceforge.net"
  10 SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${P}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 KEYWORDS="~amd64 ~ppc ~x86"
  14 IUSE="+mysql postgres +vacation xmlrpc"
  15 REQUIRED_USE="|| ( mysql postgres )"
  16
  17 DEPEND="
  18         dev-lang/php:*[unicode,imap,postgres?,xmlrpc?]
  19         vacation? (
  20                 dev-perl/DBI
  21                 virtual/perl-MIME-Base64
  22                 dev-perl/MIME-EncWords
  23                 dev-perl/Email-Valid
  24                 dev-perl/Mail-Sender
  25                 dev-perl/Log-Dispatch
  26                 dev-perl/Log-Log4perl
  27                 dev-perl/MIME-Charset
  28                 mysql? ( dev-perl/DBD-mysql )
  29                 postgres? ( dev-perl/DBD-Pg )
  30          )
  31         xmlrpc? ( dev-php/ZendFramework[-minimal] )
  32 "
  33
  34 RDEPEND="${DEPEND}
  35         virtual/httpd-php
  36         mysql? ( || ( dev-lang/php[mysqli] dev-lang/php[mysql] ) )"
  37
  38 need_httpd_cgi
  39
  40 pkg_setup() {
  41         webapp_pkg_setup
  42
  43         if use vacation; then
  44                 enewgroup vacation
  45                 enewuser vacation -1 -1 -1 vacation
  46         fi
  47 }
  48
  49 src_install() {
  50         webapp_src_preinst
  51
  52         if use vacation; then
  53                 insinto /var/spool/vacation
  54                 newins VIRTUAL_VACATION/vacation.pl vacation.pl-${SLOT}
  55                 fowners vacation:vacation /var/spool/vacation/vacation.pl-${SLOT}
  56                 fperms 770 /var/spool/vacation/vacation.pl-${SLOT}
  57                 dodoc VIRTUAL_VACATION/FILTER_README
  58                 newdoc VIRTUAL_VACATION/INSTALL.TXT VIRTUAL_VACATION_INSTALL.TXT
  59                 rm -r VIRTUAL_VACATION/{vacation.pl,INSTALL.TXT,tests,FILTER_README} || die
  60         fi
  61
  62         insinto /usr/share/doc/${PF}/
  63         doins -r ADDITIONS
  64
  65         local docs="DOCUMENTS/*.txt INSTALL.TXT CHANGELOG.TXT"
  66         dodoc ${docs}
  67
  68         rm -rf ${docs} DOCUMENTS/ GPL-LICENSE.TXT LICENSE.TXT debian/ tests/ ADDITIONS/
  69
  70         insinto "${MY_HTDOCSDIR}"
  71         doins -r .
  72
  73         webapp_configfile "${MY_HTDOCSDIR}"/config.inc.php
  74
  75         webapp_postinst_txt en "${FILESDIR}"/postinstall-en-2.3.txt
  76         webapp_src_install
  77 }
  78
  79 pkg_postinst() {
  80         webapp_pkg_postinst
  81         if use vacation; then
  82                 # portage does not update owners of directories (feature :)
  83                 chown vacation:vacation "${ROOT}"/var/spool/vacation/
  84                 einfo "/var/spool/vacation/vacation.pl symlink was updated to:"
  85                 einfo "/var/spool/vacation/vacation.pl-${SLOT}"
  86                 ln -sf "${ROOT}"/var/spool/vacation/vacation.pl{-${SLOT},} || die
  87         fi
  88 }
  89
  90 pkg_postrm() {
  91         # Make sure we don't leave broken vacation.pl symlink
  92         find -L "${ROOT}"/var/spool/vacation/ -type l -delete
  93         if [[ ! -e "${ROOT}"/var/spool/vacation/vacation.pl ]] &&
  94                 path_exists "${ROOT}"/var/spool/vacation/vacation.pl-*; then
  95                 ln -s $(LC_ALL=C ls -1 /var/spool/vacation/vacation.pl-* | tail -n1) \
  96                         "${ROOT}"/var/spool/vacation/vacation.pl || die
  97                 ewarn "/var/spool/vacation/vacation.pl was updated to point on most"
  98                 ewarn "recent verion, but please, do your own checks"
  99         fi
 100 }