www-apps/nanoc-core/nanoc-core-4.11.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby24 ruby25 ruby26"
   6
   7 RUBY_FAKEGEM_EXTRADOC="NEWS.md README.md"
   8 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
   9
  10 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  11
  12 inherit ruby-fakegem
  13
  14 DESCRIPTION="nanoc is a simple but very flexible static site generator written in Ruby"
  15 HOMEPAGE="https://nanoc.ws/"
  16 SRC_URI="https://github.com/nanoc/nanoc/archive/${PV}.tar.gz -> ${P}.tar.gz"
  17 LICENSE="MIT"
  18
  19 KEYWORDS="~amd64"
  20 SLOT="0"
  21 IUSE="${IUSE} minimal"
  22
  23 DEPEND+="test? ( app-text/asciidoc app-text/highlight )"
  24
  25 RUBY_S="nanoc-${PV}/nanoc-core"
  26
  27 ruby_add_rdepend "
  28         dev-ruby/ddmemoize:1
  29         dev-ruby/ddmetrics:1
  30         dev-ruby/ddplugin:1
  31         =dev-ruby/hamster-3*
  32         >=dev-ruby/json_schema-0.19:0
  33         dev-ruby/zeitwerk:1
  34 "
  35
  36 ruby_add_bdepend "test? (
  37         dev-ruby/bundler
  38         dev-ruby/rspec:3
  39         dev-ruby/rspec-its
  40         dev-ruby/fuubar
  41         dev-ruby/minitest
  42         dev-ruby/timecop
  43         dev-ruby/yard
  44 )
  45 "
  46
  47 all_ruby_prepare() {
  48         # Avoid unneeded development dependencies
  49         sed -i -e '/simplecov/I s:^:#:' \
  50                 -e '/codecov/I s:^:#:' ../common/spec/spec_helper_head_core.rb || die
  51         sed -i -e '/coverall/I s:^:#:' \
  52                 -e '/rubocop/ s:^:#:' Rakefile || die
  53         sed -i -e '1i require "tmpdir"; require "pathname"' spec/spec_helper.rb || die
  54
  55         echo "-r ./spec/spec_helper.rb" > .rspec || die
  56
  57         sed -i -e "s:require_relative 'lib:require './lib:" ${RUBY_FAKEGEM_GEMSPEC} || die
  58
  59         # Use useable tmp dir
  60         sed -i -e 's:/tmp/whatever:'${T}'/whatever:' spec/nanoc/core/checksummer_spec.rb || die
  61 }
  62
  63 each_ruby_test() {
  64         RUBYLIB="${S}/lib" ${RUBY} -S rake spec || die
  65 }