www-apache/libapreq2/libapreq2-2.13-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit apache-module perl-module multilib
   7
   8 DESCRIPTION="A library for manipulating client request data via the Apache API"
   9 SRC_URI="mirror://apache/httpd/libapreq/${P}.tar.gz"
  10 HOMEPAGE="https://httpd.apache.org/apreq/"
  11
  12 LICENSE="Apache-2.0"
  13 SLOT="2"
  14 KEYWORDS="amd64 ppc ppc64 x86"
  15 IUSE="perl"
  16
  17 DEPEND="${DEPEND}
  18         perl? (
  19                 >=dev-perl/ExtUtils-XSBuilder-0.23
  20                 virtual/perl-version
  21                 >=www-apache/mod_perl-2
  22         )"
  23 RDEPEND="${DEPEND}"
  24
  25 APACHE2_MOD_FILE="module/apache2/.libs/mod_apreq2.so"
  26 APACHE2_MOD_CONF="76_mod_apreq"
  27 APACHE2_MOD_DEFINE="APREQ"
  28 DOCFILES="docs/html/*.html CHANGES README INSTALL MANIFEST"
  29
  30 need_apache2
  31
  32 pkg_setup() {
  33         perl_set_version
  34 }
  35
  36 src_prepare() {
  37         epatch "${FILESDIR}"/libapreq2-2.08-doc.patch
  38
  39         sed -i -e "s/PERL \$PERL_OPTS/PERL/" "${S}"/acinclude.m4 || die
  40         sed -i -e "s/PERL \$PERL_OPTS/PERL/" "${S}"/aclocal.m4 || die
  41         sed -i -e "s/PERL \$PERL_OPTS/PERL/" "${S}"/configure  || die
  42 }
  43
  44 src_configure() {
  45         econf \
  46                 --with-apache2-apxs=${APXS} \
  47                 $(use_enable perl perl-glue)
  48 }
  49
  50 src_install() {
  51         apache-module_src_install
  52
  53         make DESTDIR="${D}" INSTALLDIRS=vendor install || die "make install failed"
  54         doman docs/man/man3/*.3
  55
  56         perl_delete_localpod
  57
  58         for i in $(find "${D}" -type f -not -name '*.so'); do
  59                 if file ${i} | grep -i " text"; then
  60                         sed -i -e "s:${D}:/:g" ${i}
  61                 fi
  62         done
  63 }