sys-libs/llvm-libunwind/llvm-libunwind-3.9.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 : ${CMAKE_MAKEFILE_GENERATOR:=ninja}
   8 inherit cmake-multilib
   9
  10 MY_P="libunwind-${PV}"
  11 DESCRIPTION="C++ runtime stack unwinder from LLVM"
  12 HOMEPAGE="https://github.com/llvm-mirror/libunwind"
  13 SRC_URI="http://llvm.org/releases/${PV}/${MY_P}.src.tar.xz"
  14
  15 LICENSE="|| ( UoI-NCSA MIT )"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="debug +static-libs"
  19
  20 RDEPEND="!sys-libs/libunwind"
  21 # llvm-config and cmake files needed to get proper flags
  22 # (3.9.0 needed because cmake file install path changed)
  23 DEPEND=">=sys-devel/llvm-3.9.0[${MULTILIB_USEDEP}]"
  24
  25 S="${WORKDIR}/${MY_P}.src"
  26
  27 src_prepare() {
  28         # add switch for static-libs; accepted upstream
  29         eapply "${FILESDIR}/libunwind-3.9-cmake-static-lib.patch"
  30         default
  31 }
  32
  33 multilib_src_configure() {
  34         local libdir=$(get_libdir)
  35
  36         local mycmakeargs=(
  37                 -DLLVM_LIBDIR_SUFFIX=${libdir#lib}
  38                 -DLIBUNWIND_ENABLE_ASSERTIONS=$(usex debug)
  39                 -DLIBUNWIND_ENABLE_STATIC=$(usex static-libs)
  40         )
  41
  42         cmake-utils_src_configure
  43 }
  44
  45 multilib_src_install() {
  46         cmake-utils_src_install
  47
  48         # install headers like sys-libs/libunwind
  49         doheader "${S}"/include/*.h
  50 }