sys-libs/libieee1284/libieee1284-0.2.11-r4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit python-single-r1 multilib-minimal
   9
  10 DESCRIPTION="Library to query devices using IEEE1284"
  11 HOMEPAGE="http://cyberelk.net/tim/software/libieee1284/"
  12 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc x86"
  17 IUSE="doc python static-libs"
  18 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  19
  20 RDEPEND="
  21         python? ( ${PYTHON_DEPS} )"
  22 DEPEND="${RDEPEND}
  23         doc? (
  24                 app-text/docbook-sgml-utils
  25                 >=app-text/docbook-sgml-dtd-4.1
  26                 app-text/docbook-dsssl-stylesheets
  27                 dev-perl/XML-RegExp
  28         )"
  29
  30 pkg_setup() {
  31         use python && python-single-r1_pkg_setup
  32 }
  33
  34 multilib_src_configure() {
  35         ECONF_SOURCE="${S}" econf \
  36                 --enable-shared \
  37                 $(use_enable static-libs static) \
  38                 $(multilib_native_with python)
  39 }
  40
  41 multilib_src_install_all() {
  42         einstalldocs
  43         dodoc doc/interface*
  44
  45         if ! use static-libs; then
  46                 find "${D}" -name '*.la' -delete || die
  47         fi
  48 }