sys-libs/ldb/ldb-1.1.17-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python2_7 )
   7 PYTHON_REQ_USE="threads"
   8
   9 inherit python-single-r1 waf-utils multilib
  10
  11 DESCRIPTION="An LDAP-like embedded database"
  12 HOMEPAGE="http://ldb.samba.org"
  13 SRC_URI="http://www.samba.org/ftp/pub/${PN}/${P}.tar.gz"
  14
  15 LICENSE="LGPL-3"
  16 SLOT="0/${PV}"
  17 KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh x86 ~amd64-fbsd ~x86-fbsd"
  18 IUSE="doc"
  19
  20 RDEPEND="dev-libs/popt
  21         >=sys-libs/talloc-2.1.0[python]
  22         >=sys-libs/tevent-0.9.21[python(+)]
  23         >=sys-libs/tdb-1.2.12[python]
  24         net-nds/openldap
  25         !!<net-fs/samba-3.6.0[ldb]
  26         !!>=net-fs/samba-4.0.0[ldb]
  27         ${PYTHON_DEPS}
  28         "
  29
  30 DEPEND="dev-libs/libxslt
  31         doc? ( app-doc/doxygen )
  32         virtual/pkgconfig
  33         ${RDEPEND}"
  34
  35 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  36
  37 WAF_BINARY="${S}/buildtools/bin/waf"
  38
  39 pkg_setup() {
  40         python-single-r1_pkg_setup
  41 }
  42
  43 src_configure() {
  44         waf-utils_src_configure \
  45                 --disable-rpath \
  46                 --disable-rpath-install --bundled-libraries=NONE \
  47                 --with-modulesdir="${EPREFIX}"/usr/$(get_libdir)/samba \
  48                 --builtin-libraries=NONE
  49 }
  50
  51 src_compile(){
  52         waf-utils_src_compile
  53         use doc && doxygen Doxyfile
  54 }
  55
  56 src_test() {
  57         WAF_MAKE=1 \
  58         PATH=buildtools/bin:../../../buildtools/bin:$PATH:"${S}"/bin/shared/private/ \
  59         LD_LIBRARY_PATH=$LD_LIBRARY_PATH:"${S}"/bin/shared/private/:"${S}"/bin/shared waf test || die
  60 }
  61
  62 src_install() {
  63         waf-utils_src_install
  64
  65         if use doc; then
  66                 dohtml -r apidocs/html/*
  67                 doman  apidocs/man/man3/*.3
  68         fi
  69 }
  70
  71 pkg_postinst() {
  72         if has_version sys-auth/sssd; then
  73                 ewarn "You have sssd installed. It is known to break after ldb upgrades,"
  74                 ewarn "so please try to rebuild it before reporting bugs."
  75                 ewarn "See https://bugs.gentoo.org/404281"
  76         fi
  77 }