sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P="${P/_rc/rc}"
   7 inherit qmake-utils
   8
   9 DESCRIPTION="Multi-platform helper library for other libraries"
  10 HOMEPAGE="https://www.aquamaniac.de/sites/aqbanking/index.php"
  11 SRC_URI="https://www.aquamaniac.de/rdm/attachments/download/234/${MY_P}.tar.gz"
  12
  13 LICENSE="LGPL-2.1"
  14 SLOT="0/79" # correspond with libgwenhywfar.so version
  15 KEYWORDS="amd64 ~hppa ~ppc ~ppc64 ~sparc x86"
  16 IUSE="debug designer doc fox gtk libressl qml qt5 sensors serialport test webkit"
  17
  18 REQUIRED_USE="designer? ( qt5 ) qml? ( qt5 ) sensors? ( qt5 ) serialport? ( qt5 ) webkit? ( qt5 )"
  19
  20 BDEPEND="
  21         sys-devel/gettext
  22         virtual/pkgconfig
  23         doc? ( app-doc/doxygen )
  24 "
  25 COMMON_DEPEND="
  26         dev-libs/libgcrypt:0=
  27         dev-libs/libgpg-error
  28         libressl? ( dev-libs/libressl:0= )
  29         !libressl? ( dev-libs/openssl:0= )
  30         net-libs/gnutls:=
  31         virtual/libiconv
  32         virtual/libintl
  33         virtual/opengl
  34         designer? ( dev-qt/designer:5 )
  35         fox? ( x11-libs/fox:1.6 )
  36         gtk? ( x11-libs/gtk+:3 )
  37         qml? ( dev-qt/qtdeclarative:5 )
  38         qt5? (
  39                 dev-qt/qtconcurrent:5
  40                 dev-qt/qtcore:5
  41                 dev-qt/qtdbus:5
  42                 dev-qt/qtgui:5
  43                 dev-qt/qthelp:5
  44                 dev-qt/qtmultimedia:5[widgets]
  45                 dev-qt/qtnetwork:5
  46                 dev-qt/qtopengl:5
  47                 dev-qt/qtprintsupport:5
  48                 dev-qt/qtscript:5
  49                 dev-qt/qtsql:5
  50                 dev-qt/qtsvg:5
  51                 dev-qt/qtwidgets:5
  52                 dev-qt/qtx11extras:5
  53                 dev-qt/qtxml:5
  54                 dev-qt/qtxmlpatterns:5
  55         )
  56         sensors? ( dev-qt/qtsensors:5 )
  57         serialport? ( dev-qt/qtserialport:5 )
  58         webkit? ( dev-qt/qtwebkit:5 )
  59 "
  60 DEPEND="${COMMON_DEPEND}
  61         test? ( dev-qt/qttest:5 )
  62 "
  63 RDEPEND="${COMMON_DEPEND}
  64         gtk? ( !<app-office/gnucash-3.7[aqbanking] )
  65 "
  66
  67 # broken upstream, reported but got no reply
  68 RESTRICT+=" test"
  69
  70 S="${WORKDIR}/${MY_P}"
  71
  72 src_configure() {
  73         disableQtModule() {
  74                 local module
  75                 for module in ${@}; do
  76                         sed -e "/qtHaveModule(${module})/s|^|#DONT|" -i configure || die
  77                 done
  78         }
  79
  80         use designer || disableQtModule designer uitools
  81         use qml || disableQtModule qml qmltest
  82         use sensors || disableQtModule sensors
  83         use serialport || disableQtModule serialport
  84         use test || disableQtModule testlib
  85         use webkit || disableQtModule webkit webkitwidgets
  86
  87         local guis=()
  88         use fox && guis+=( fox16 )
  89         use gtk && guis+=( gtk3 )
  90         use qt5 && guis+=( qt5 )
  91
  92         local myeconfargs=(
  93                 --enable-ssl
  94                 --with-docpath="${EPREFIX}/usr/share/doc/${PF}/apidoc"
  95                 $(use_enable debug)
  96                 $(use_enable doc full-doc)
  97         )
  98         use qt5 && myeconfargs+=(
  99                 --with-qt5-moc="$(qt5_get_bindir)/moc"
 100                 --with-qt5-qmake="$(qt5_get_bindir)/qmake"
 101         )
 102
 103         guis_config="--with-guis=${guis[@]}"
 104         econf "${myeconfargs[@]}" "${guis_config}"
 105 }
 106
 107 src_compile() {
 108         emake
 109         use doc && emake srcdoc
 110 }
 111
 112 src_install() {
 113         default
 114         use doc && emake DESTDIR="${D}" install-srcdoc
 115         find "${D}" -name '*.la' -type f -delete || die
 116 }