sys-kernel/ck-sources/ck-sources-4.9.123.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 ETYPE="sources"
   6 KEYWORDS="~amd64 ~x86"
   7
   8 HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches/
   9         http://kernel.kolivas.org/"
  10
  11 IUSE="experimental"
  12
  13 K_WANT_GENPATCHES="base extras experimental"
  14 K_GENPATCHES_VER="127"
  15 K_SECURITY_UNSUPPORTED="1"
  16 K_DEBLOB_AVAILABLE="1"
  17
  18 PYTHON_COMPAT=( python2_7 )
  19 inherit python-any-r1 kernel-2
  20 detect_version
  21 detect_arch
  22
  23 DEPEND="deblob? ( ${PYTHON_DEPS} )"
  24
  25 K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"
  26
  27 DESCRIPTION="Gentoo's genpatches for Linux ${K_BRANCH_ID}, with Con Kolivas' MuQSS process scheduler."
  28
  29 MUQSS_VERSION="150"
  30 MUQSS_FILE="${K_BRANCH_ID}-sched-MuQSS_${MUQSS_VERSION}.patch"
  31 MUQSS_BASE_URL="http://ck.kolivas.org/patches/muqss/4.0"
  32
  33 # clearly identify package name in distrdir
  34 MUQSS_DISTNAME="${PN}-${K_BRANCH_ID}-muqss.patch"
  35
  36 CK_LVER_URL="${MUQSS_BASE_URL}/${K_BRANCH_ID}"
  37 CK_URI="${CK_LVER_URL}/${MUQSS_FILE} -> ${MUQSS_DISTNAME}"
  38
  39 # solves bug #606866 (Fix build for CONFIG_FREEZER disabled.x)
  40 FRZR_HASH="7de569950716147ed436b27936628ee3ab5b45cc"
  41 FRZR_FILE="${PN}-4.9-freezer-fix.patch"
  42 FRZR_URI="https://github.com/ckolivas/linux/commit/${FRZR_HASH}.patch -> ${FRZR_FILE}"
  43
  44 SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI} ${CK_URI} ${FRZR_URI}"
  45
  46 UNIPATCH_LIST="${DISTDIR}/${MUQSS_DISTNAME} ${DISTDIR}/${FRZR_FILE}"
  47 UNIPATCH_STRICTORDER="yes"
  48
  49 pkg_setup() {
  50         use deblob && python-any-r1_pkg_setup
  51         kernel-2_pkg_setup
  52 }
  53
  54 pkg_postinst() {
  55         elog "CPU optimizations patch (from genpatches) is off by default."
  56         elog "Set USE=\"experimental\" if you need this patch / feature."
  57         elog "This can be set in /etc/portage/package.use (or make.conf)"
  58         elog "make menuconfig as usual to edit .config for this feature."
  59 }