sys-kernel/aufs-sources/aufs-sources-5.2.18.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 ETYPE="sources"
   7 K_WANT_GENPATCHES="base extras experimental"
   8 K_GENPATCHES_VER=18
   9 UNIPATCH_STRICTORDER=1
  10 inherit kernel-2 eutils readme.gentoo-r1
  11
  12 AUFS_VERSION=5.2.5+_p20190909
  13 AUFS_TARBALL="aufs-sources-${AUFS_VERSION}.tar.xz"
  14 # git archive -v --remote=git://git.code.sf.net/p/aufs/aufs5-standalone aufs${AUFS_VERSION/_p*} > aufs-sources-${AUFS_VERSION}.tar
  15 AUFS_URI="https://dev.gentoo.org/~jlec/distfiles/${AUFS_TARBALL}"
  16
  17 KEYWORDS="~amd64 ~x86"
  18 HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches http://aufs.sourceforge.net/"
  19 IUSE="experimental module vanilla"
  20
  21 DESCRIPTION="Full sources (incl. Gentoo patchset) for the linux kernel tree and aufs5 support"
  22 SRC_URI="
  23         ${KERNEL_URI}
  24         ${ARCH_URI}
  25         ${AUFS_URI}
  26         !vanilla? ( ${GENPATCHES_URI} )
  27         "
  28
  29 PDEPEND="=sys-fs/aufs-util-4*"
  30
  31 README_GENTOO_SUFFIX="-r1"
  32
  33 src_unpack() {
  34         detect_version
  35         detect_arch
  36         if use vanilla; then
  37                 unset UNIPATCH_LIST_GENPATCHES UNIPATCH_LIST_DEFAULT
  38                 ewarn "You are using USE=vanilla"
  39                 ewarn "This will drop all support from the gentoo kernel security team"
  40         fi
  41
  42         UNIPATCH_LIST="
  43                 "${WORKDIR}"/aufs5-kbuild.patch
  44                 "${WORKDIR}"/aufs5-base.patch
  45                 "${WORKDIR}"/aufs5-mmap.patch"
  46
  47         use module && UNIPATCH_LIST+=" "${WORKDIR}"/aufs5-standalone.patch"
  48
  49         unpack ${AUFS_TARBALL}
  50
  51         einfo "Using aufs5 version: ${AUFS_VERSION}"
  52
  53         kernel-2_src_unpack
  54 }
  55
  56 src_prepare() {
  57         kernel-2_src_prepare
  58         if ! use module; then
  59                 sed -e 's:tristate:bool:g' -i "${WORKDIR}"/fs/aufs/Kconfig || die
  60         fi
  61         cp -f "${WORKDIR}"/include/uapi/linux/aufs_type.h include/uapi/linux/aufs_type.h || die
  62         cp -rf "${WORKDIR}"/{Documentation,fs} . || die
  63 }
  64
  65 src_install() {
  66         kernel-2_src_install
  67         dodoc "${WORKDIR}"/{aufs5-loopback,vfs-ino,tmpfs-idr}.patch
  68         docompress -x /usr/share/doc/${PF}/{aufs5-loopback,vfs-ino,tmpfs-idr}.patch
  69         readme.gentoo_create_doc
  70 }
  71
  72 pkg_postinst() {
  73         kernel-2_pkg_postinst
  74         einfo "For more info on this patchset, and how to report problems, see:"
  75         einfo "${HOMEPAGE}"
  76         has_version sys-fs/aufs-util || \
  77                 elog "In order to use aufs FS you need to install sys-fs/aufs-util"
  78
  79         readme.gentoo_print_elog
  80 }
  81
  82 pkg_postrm() {
  83         kernel-2_pkg_postrm
  84 }