sys-fs/mtpfs/mtpfs-1.1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6
   7 DESCRIPTION="A FUSE filesystem providing access to MTP devices"
   8 HOMEPAGE="http://www.adebenham.com/mtpfs/"
   9 SRC_URI="http://www.adebenham.com/files/mtp/${P}.tar.gz"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="debug mad"
  15
  16 RDEPEND="dev-libs/glib:2
  17         >=media-libs/libmtp-1.1.2
  18         sys-fs/fuse
  19         mad? (
  20                 media-libs/libid3tag
  21                 media-libs/libmad
  22         )"
  23 DEPEND="${RDEPEND}
  24         virtual/pkgconfig"
  25
  26 DOCS=(AUTHORS NEWS README)
  27
  28 src_prepare() {
  29         sed -e "/#include <string.h>/ a\
  30                 #include <stdlib.h>" -i mtpfs.h id3read.c || die #implicit
  31 }
  32
  33 src_configure() {
  34         econf $(use_enable debug) \
  35                 $(use_enable mad)
  36 }
  37
  38 pkg_postinst() {
  39         einfo "To mount your MTP device, issue:"
  40         einfo "    /usr/bin/mtpfs <mountpoint>"
  41         echo
  42         einfo "To unmount your MTP device, issue:"
  43         einfo "    /usr/bin/fusermount -u <mountpoint>"
  44
  45         if use debug; then
  46                 echo
  47                 einfo "You have enabled debugging output."
  48                 einfo "Please make sure you run mtpfs with the -d flag."
  49         fi
  50 }