sys-fs/mergerfs/mergerfs-2.29.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="A featureful union filesystem"
   7 HOMEPAGE="https://github.com/trapexit/mergerfs"
   8
   9 SRC_URI="https://github.com/trapexit/mergerfs/archive/${PV}.tar.gz -> ${P}.tar.gz"
  10 KEYWORDS="~amd64 ~x86"
  11
  12 # Vendorized libfuse that's bundled is under LGPL-2.1.
  13 LICENSE="ISC LGPL-2.1"
  14 SLOT="0"
  15 IUSE="+xattr"
  16
  17 DEPEND="
  18         xattr? ( sys-apps/attr )
  19 "
  20
  21 RDEPEND="${DEPEND}"
  22
  23 BDEPEND="sys-devel/gettext"
  24
  25 src_prepare() {
  26         default
  27
  28         # Hand made build system at it's finest.
  29         echo -e "#!/bin/sh\ntrue" >tools/update-version || die
  30         echo "#pragma once" >src/version.hpp || die
  31         echo "static const char MERGERFS_VERSION[] = \"${PV}\";" >>src/version.hpp || die
  32
  33         if ! use xattr; then
  34                 sed 's%USE_XATTR = 1%USE_XATTR = 0%g' -i Makefile || die
  35         fi
  36 }
  37
  38 src_install() {
  39         dobin build/mergerfs
  40         dosym mergerfs /usr/bin/mount.mergerfs
  41         dodoc README.md
  42         doman man/mergerfs.1
  43 }