sys-fs/f2fs-tools/f2fs-tools-1.13.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Tools for Flash-Friendly File System (F2FS)"
   9 HOMEPAGE="https://git.kernel.org/cgit/linux/kernel/git/jaegeuk/f2fs-tools.git/about/"
  10 SRC_URI="https://dev.gentoo.org/~zlogene/distfiles/${CATEGORY}/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0/6"
  14 KEYWORDS="amd64 arm ~arm64 ~mips ppc ppc64 x86"
  15 IUSE="selinux"
  16
  17 RDEPEND="
  18         selinux? ( sys-libs/libselinux )
  19         elibc_musl? ( sys-libs/queue-standalone )"
  20 DEPEND="${RDEPEND}"
  21
  22 src_prepare() {
  23         default
  24         eautoreconf
  25 }
  26
  27 src_configure() {
  28         #This is required to install to /sbin, bug #481110
  29         econf \
  30                 --bindir="${EPREFIX}"/sbin \
  31                 --disable-static \
  32                 $(use_with selinux)
  33 }
  34
  35 src_install() {
  36         default
  37         find "${D}" -name "*.la" -delete || die
  38 }