sys-devel/llvm/llvm-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 : ${CMAKE_MAKEFILE_GENERATOR:=ninja}
   7 # (needed due to CMAKE_BUILD_TYPE != Gentoo)
   8 CMAKE_MIN_VERSION=3.7.0-r1
   9 PYTHON_COMPAT=( python2_7 )
  10
  11 inherit cmake-utils eapi7-ver flag-o-matic git-r3 multilib-minimal \
  12         multiprocessing pax-utils python-any-r1 toolchain-funcs
  13
  14 DESCRIPTION="Low Level Virtual Machine"
  15 HOMEPAGE="https://llvm.org/"
  16 SRC_URI=""
  17 EGIT_REPO_URI="https://git.llvm.org/git/llvm.git
  18         https://github.com/llvm-mirror/llvm.git"
  19
  20 # Those are in lib/Targets, without explicit CMakeLists.txt mention
  21 ALL_LLVM_EXPERIMENTAL_TARGETS=( AVR Nios2 RISCV WebAssembly )
  22 # Keep in sync with CMakeLists.txt
  23 ALL_LLVM_TARGETS=( AArch64 AMDGPU ARM BPF Hexagon Lanai Mips MSP430
  24         NVPTX PowerPC Sparc SystemZ X86 XCore
  25         "${ALL_LLVM_EXPERIMENTAL_TARGETS[@]}" )
  26 ALL_LLVM_TARGETS=( "${ALL_LLVM_TARGETS[@]/#/llvm_targets_}" )
  27
  28 # Additional licenses:
  29 # 1. OpenBSD regex: Henry Spencer's license ('rc' in Gentoo) + BSD.
  30 # 2. ARM backend: LLVM Software Grant by ARM.
  31 # 3. MD5 code: public-domain.
  32 # 4. Tests (not installed):
  33 #  a. gtest: BSD.
  34 #  b. YAML tests: MIT.
  35
  36 LICENSE="UoI-NCSA rc BSD public-domain
  37         llvm_targets_ARM? ( LLVM-Grant )"
  38 SLOT="9"
  39 KEYWORDS=""
  40 IUSE="debug doc exegesis gold libedit +libffi ncurses test xar xml
  41         kernel_Darwin ${ALL_LLVM_TARGETS[*]}"
  42 RESTRICT="!test? ( test )"
  43
  44 RDEPEND="
  45         sys-libs/zlib:0=
  46         exegesis? ( dev-libs/libpfm:= )
  47         gold? ( >=sys-devel/binutils-2.22:*[cxx] )
  48         libedit? ( dev-libs/libedit:0=[${MULTILIB_USEDEP}] )
  49         libffi? ( >=virtual/libffi-3.0.13-r1:0=[${MULTILIB_USEDEP}] )
  50         ncurses? ( >=sys-libs/ncurses-5.9-r3:0=[${MULTILIB_USEDEP}] )
  51         xar? ( app-arch/xar )
  52         xml? ( dev-libs/libxml2:2=[${MULTILIB_USEDEP}] )"
  53 # configparser-3.2 breaks the build (3.3 or none at all are fine)
  54 DEPEND="${RDEPEND}
  55         dev-lang/perl
  56         || ( >=sys-devel/gcc-3.0 >=sys-devel/llvm-3.5
  57                 ( >=sys-freebsd/freebsd-lib-9.1-r10 sys-libs/libcxx )
  58         )
  59         kernel_Darwin? (
  60                 <sys-libs/libcxx-$(ver_cut 1-3).9999
  61                 >=sys-devel/binutils-apple-5.1
  62         )
  63         doc? ( $(python_gen_any_dep '
  64                 dev-python/recommonmark[${PYTHON_USEDEP}]
  65                 dev-python/sphinx[${PYTHON_USEDEP}]
  66         ') )
  67         !doc? ( ${PYTHON_DEPS} )
  68         gold? ( sys-libs/binutils-libs )
  69         libffi? ( virtual/pkgconfig )
  70         !!<dev-python/configparser-3.3.0.2
  71         ${PYTHON_DEPS}"
  72 # There are no file collisions between these versions but having :0
  73 # installed means llvm-config there will take precedence.
  74 RDEPEND="${RDEPEND}
  75         !sys-devel/llvm:0"
  76 PDEPEND="sys-devel/llvm-common
  77         gold? ( >=sys-devel/llvmgold-${SLOT} )"
  78
  79 REQUIRED_USE="${PYTHON_REQUIRED_USE}
  80         || ( ${ALL_LLVM_TARGETS[*]} )"
  81
  82 # least intrusive of all
  83 CMAKE_BUILD_TYPE=RelWithDebInfo
  84
  85 python_check_deps() {
  86         use doc || return 0
  87
  88         has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" &&
  89         has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
  90 }
  91
  92 src_prepare() {
  93         # Fix llvm-config for shared linking and sane flags
  94         # https://bugs.gentoo.org/show_bug.cgi?id=565358
  95         eapply "${FILESDIR}"/9999/0007-llvm-config-Clean-up-exported-values-update-for-shar.patch
  96
  97         # disable use of SDK on OSX, bug #568758
  98         sed -i -e 's/xcrun/false/' utils/lit/lit/util.py || die
  99
 100         # User patches + QA
 101         cmake-utils_src_prepare
 102 }
 103
 104 # Is LLVM being linked against libc++?
 105 is_libcxx_linked() {
 106         local code='#include <ciso646>
 107 #if defined(_LIBCPP_VERSION)
 108         HAVE_LIBCXX
 109 #endif
 110 '
 111         local out=$($(tc-getCXX) ${CXXFLAGS} ${CPPFLAGS} -x c++ -E -P - <<<"${code}") || return 1
 112
 113         [[ ${out} == *HAVE_LIBCXX* ]]
 114 }
 115
 116 multilib_src_configure() {
 117         local ffi_cflags ffi_ldflags
 118         if use libffi; then
 119                 ffi_cflags=$($(tc-getPKG_CONFIG) --cflags-only-I libffi)
 120                 ffi_ldflags=$($(tc-getPKG_CONFIG) --libs-only-L libffi)
 121         fi
 122
 123         local libdir=$(get_libdir)
 124         local mycmakeargs=(
 125                 # disable appending VCS revision to the version to improve
 126                 # direct cache hit ratio
 127                 -DLLVM_APPEND_VC_REV=OFF
 128                 -DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/lib/llvm/${SLOT}"
 129                 -DLLVM_LIBDIR_SUFFIX=${libdir#lib}
 130
 131                 -DBUILD_SHARED_LIBS=ON
 132                 # cheap hack: LLVM combines both anyway, and the only difference
 133                 # is that the former list is explicitly verified at cmake time
 134                 -DLLVM_TARGETS_TO_BUILD=""
 135                 -DLLVM_EXPERIMENTAL_TARGETS_TO_BUILD="${LLVM_TARGETS// /;}"
 136                 -DLLVM_BUILD_TESTS=$(usex test)
 137
 138                 -DLLVM_ENABLE_FFI=$(usex libffi)
 139                 -DLLVM_ENABLE_LIBEDIT=$(usex libedit)
 140                 -DLLVM_ENABLE_TERMINFO=$(usex ncurses)
 141                 -DLLVM_ENABLE_LIBXML2=$(usex xml)
 142                 -DLLVM_ENABLE_ASSERTIONS=$(usex debug)
 143                 -DLLVM_ENABLE_LIBPFM=$(usex exegesis)
 144                 -DLLVM_ENABLE_EH=ON
 145                 -DLLVM_ENABLE_RTTI=ON
 146
 147                 -DWITH_POLLY=OFF # TODO
 148
 149                 -DLLVM_HOST_TRIPLE="${CHOST}"
 150
 151                 -DFFI_INCLUDE_DIR="${ffi_cflags#-I}"
 152                 -DFFI_LIBRARY_DIR="${ffi_ldflags#-L}"
 153                 # used only for llvm-objdump tool
 154                 -DHAVE_LIBXAR=$(multilib_native_usex xar 1 0)
 155
 156                 # disable OCaml bindings (now in dev-ml/llvm-ocaml)
 157                 -DOCAMLFIND=NO
 158         )
 159
 160         if is_libcxx_linked; then
 161                 # Smart hack: alter version suffix -> SOVERSION when linking
 162                 # against libc++. This way we won't end up mixing LLVM libc++
 163                 # libraries with libstdc++ clang, and the other way around.
 164                 mycmakeargs+=(
 165                         -DLLVM_VERSION_SUFFIX="libcxx"
 166                 )
 167         fi
 168
 169 #       Note: go bindings have no CMake rules at the moment
 170 #       but let's kill the check in case they are introduced
 171 #       if ! multilib_is_native_abi || ! use go; then
 172                 mycmakeargs+=(
 173                         -DGO_EXECUTABLE=GO_EXECUTABLE-NOTFOUND
 174                 )
 175 #       fi
 176
 177         use test && mycmakeargs+=(
 178                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
 179         )
 180
 181         if multilib_is_native_abi; then
 182                 mycmakeargs+=(
 183                         -DLLVM_BUILD_DOCS=$(usex doc)
 184                         -DLLVM_ENABLE_OCAMLDOC=OFF
 185                         -DLLVM_ENABLE_SPHINX=$(usex doc)
 186                         -DLLVM_ENABLE_DOXYGEN=OFF
 187                         -DLLVM_INSTALL_UTILS=ON
 188                 )
 189                 use doc && mycmakeargs+=(
 190                         -DCMAKE_INSTALL_MANDIR="${EPREFIX}/usr/lib/llvm/${SLOT}/share/man"
 191                         -DLLVM_INSTALL_SPHINX_HTML_DIR="${EPREFIX}/usr/share/doc/${PF}/html"
 192                         -DSPHINX_WARNINGS_AS_ERRORS=OFF
 193                 )
 194                 use gold && mycmakeargs+=(
 195                         -DLLVM_BINUTILS_INCDIR="${EPREFIX}"/usr/include
 196                 )
 197         fi
 198
 199         if tc-is-cross-compiler; then
 200                 local tblgen="${EPREFIX}/usr/lib/llvm/${SLOT}/bin/llvm-tblgen"
 201                 [[ -x "${tblgen}" ]] \
 202                         || die "${tblgen} not found or usable"
 203                 mycmakeargs+=(
 204                         -DCMAKE_CROSSCOMPILING=ON
 205                         -DLLVM_TABLEGEN="${tblgen}"
 206                 )
 207         fi
 208
 209         # workaround BMI bug in gcc-7 (fixed in 7.4)
 210         # https://bugs.gentoo.org/649880
 211         # apply only to x86, https://bugs.gentoo.org/650506
 212         if tc-is-gcc && [[ ${MULTILIB_ABI_FLAG} == abi_x86* ]] &&
 213                         [[ $(gcc-major-version) -eq 7 && $(gcc-minor-version) -lt 4 ]]
 214         then
 215                 local CFLAGS="${CFLAGS} -mno-bmi"
 216                 local CXXFLAGS="${CXXFLAGS} -mno-bmi"
 217         fi
 218
 219         # LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
 220         use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
 221         cmake-utils_src_configure
 222 }
 223
 224 multilib_src_compile() {
 225         cmake-utils_src_compile
 226
 227         pax-mark m "${BUILD_DIR}"/bin/llvm-rtdyld
 228         pax-mark m "${BUILD_DIR}"/bin/lli
 229         pax-mark m "${BUILD_DIR}"/bin/lli-child-target
 230
 231         if use test; then
 232                 pax-mark m "${BUILD_DIR}"/unittests/ExecutionEngine/Orc/OrcJITTests
 233                 pax-mark m "${BUILD_DIR}"/unittests/ExecutionEngine/MCJIT/MCJITTests
 234                 pax-mark m "${BUILD_DIR}"/unittests/Support/SupportTests
 235         fi
 236 }
 237
 238 multilib_src_test() {
 239         # respect TMPDIR!
 240         local -x LIT_PRESERVES_TMP=1
 241         cmake-utils_src_make check
 242 }
 243
 244 src_install() {
 245         local MULTILIB_CHOST_TOOLS=(
 246                 /usr/lib/llvm/${SLOT}/bin/llvm-config
 247         )
 248
 249         local MULTILIB_WRAPPED_HEADERS=(
 250                 /usr/include/llvm/Config/llvm-config.h
 251         )
 252
 253         local LLVM_LDPATHS=()
 254         multilib-minimal_src_install
 255
 256         # move wrapped headers back
 257         mv "${ED%/}"/usr/include "${ED%/}"/usr/lib/llvm/${SLOT}/include || die
 258 }
 259
 260 multilib_src_install() {
 261         cmake-utils_src_install
 262
 263         # move headers to /usr/include for wrapping
 264         rm -rf "${ED%/}"/usr/include || die
 265         mv "${ED%/}"/usr/lib/llvm/${SLOT}/include "${ED%/}"/usr/include || die
 266
 267         LLVM_LDPATHS+=( "${EPREFIX}/usr/lib/llvm/${SLOT}/$(get_libdir)" )
 268 }
 269
 270 multilib_src_install_all() {
 271         local revord=$(( 9999 - ${SLOT} ))
 272         newenvd - "10llvm-${revord}" <<-_EOF_
 273                 PATH="${EPREFIX}/usr/lib/llvm/${SLOT}/bin"
 274                 # we need to duplicate it in ROOTPATH for Portage to respect...
 275                 ROOTPATH="${EPREFIX}/usr/lib/llvm/${SLOT}/bin"
 276                 MANPATH="${EPREFIX}/usr/lib/llvm/${SLOT}/share/man"
 277                 LDPATH="$( IFS=:; echo "${LLVM_LDPATHS[*]}" )"
 278         _EOF_
 279
 280         docompress "/usr/lib/llvm/${SLOT}/share/man"
 281 }
 282
 283 pkg_postinst() {
 284         elog "You can find additional opt-viewer utility scripts in:"
 285         elog "  ${EROOT%/}/usr/lib/llvm/${SLOT}/share/opt-viewer"
 286         elog "To use these scripts, you will need Python 2.7 along with the following"
 287         elog "packages:"
 288         elog "  dev-python/pygments (for opt-viewer)"
 289         elog "  dev-python/pyyaml (for all of them)"
 290 }