sys-devel/llvm/llvm-6.0.9999.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 : ${CMAKE_MAKEFILE_GENERATOR:=ninja}
   7 # (needed due to CMAKE_BUILD_TYPE != Gentoo)
   8 CMAKE_MIN_VERSION=3.7.0-r1
   9 PYTHON_COMPAT=( python2_7 )
  10
  11 inherit cmake-utils eapi7-ver flag-o-matic git-r3 multilib-minimal \
  12         multiprocessing pax-utils python-any-r1 toolchain-funcs
  13
  14 DESCRIPTION="Low Level Virtual Machine"
  15 HOMEPAGE="https://llvm.org/"
  16 SRC_URI=""
  17 EGIT_REPO_URI="https://git.llvm.org/git/llvm.git
  18         https://github.com/llvm-mirror/llvm.git"
  19 EGIT_BRANCH="release_60"
  20
  21 # Keep in sync with CMakeLists.txt
  22 ALL_LLVM_TARGETS=( AArch64 AMDGPU ARM BPF Hexagon Lanai Mips MSP430
  23         NVPTX PowerPC Sparc SystemZ X86 XCore )
  24 ALL_LLVM_TARGETS=( "${ALL_LLVM_TARGETS[@]/#/llvm_targets_}" )
  25
  26 # Additional licenses:
  27 # 1. OpenBSD regex: Henry Spencer's license ('rc' in Gentoo) + BSD.
  28 # 2. ARM backend: LLVM Software Grant by ARM.
  29 # 3. MD5 code: public-domain.
  30 # 4. Tests (not installed):
  31 #  a. gtest: BSD.
  32 #  b. YAML tests: MIT.
  33
  34 LICENSE="UoI-NCSA rc BSD public-domain
  35         llvm_targets_ARM? ( LLVM-Grant )"
  36 SLOT="$(ver_cut 1)"
  37 KEYWORDS=""
  38 IUSE="debug doc gold libedit +libffi ncurses test xar xml
  39         kernel_Darwin ${ALL_LLVM_TARGETS[*]}"
  40 RESTRICT="!test? ( test )"
  41
  42 RDEPEND="
  43         sys-libs/zlib:0=
  44         gold? ( >=sys-devel/binutils-2.22:*[cxx] )
  45         libedit? ( dev-libs/libedit:0=[${MULTILIB_USEDEP}] )
  46         libffi? ( >=virtual/libffi-3.0.13-r1:0=[${MULTILIB_USEDEP}] )
  47         ncurses? ( >=sys-libs/ncurses-5.9-r3:0=[${MULTILIB_USEDEP}] )
  48         xar? ( app-arch/xar )
  49         xml? ( dev-libs/libxml2:2=[${MULTILIB_USEDEP}] )"
  50 # configparser-3.2 breaks the build (3.3 or none at all are fine)
  51 DEPEND="${RDEPEND}
  52         dev-lang/perl
  53         || ( >=sys-devel/gcc-3.0 >=sys-devel/llvm-3.5
  54                 ( >=sys-freebsd/freebsd-lib-9.1-r10 sys-libs/libcxx )
  55         )
  56         kernel_Darwin? (
  57                 <sys-libs/libcxx-$(ver_cut 1-3).9999
  58                 >=sys-devel/binutils-apple-5.1
  59         )
  60         doc? ( dev-python/sphinx )
  61         gold? ( sys-libs/binutils-libs )
  62         libffi? ( virtual/pkgconfig )
  63         !!<dev-python/configparser-3.3.0.2
  64         ${PYTHON_DEPS}"
  65 # There are no file collisions between these versions but having :0
  66 # installed means llvm-config there will take precedence.
  67 RDEPEND="${RDEPEND}
  68         !sys-devel/llvm:0"
  69 PDEPEND="sys-devel/llvm-common
  70         gold? ( >=sys-devel/llvmgold-${SLOT} )"
  71
  72 REQUIRED_USE="${PYTHON_REQUIRED_USE}
  73         || ( ${ALL_LLVM_TARGETS[*]} )"
  74
  75 # least intrusive of all
  76 CMAKE_BUILD_TYPE=RelWithDebInfo
  77
  78 src_prepare() {
  79         # Fix llvm-config for shared linking and sane flags
  80         # https://bugs.gentoo.org/show_bug.cgi?id=565358
  81         eapply "${FILESDIR}"/9999/0007-llvm-config-Clean-up-exported-values-update-for-shar.patch
  82
  83         # Fix appending -Wl,-rpath-link on non-Linux (-> FreeBSD).
  84         eapply "${FILESDIR}"/6.0.9999/0001-cmake-Append-Wl-rpath-link-conditionally-to-GNULD.patch
  85
  86         # disable use of SDK on OSX, bug #568758
  87         sed -i -e 's/xcrun/false/' utils/lit/lit/util.py || die
  88
  89         # User patches + QA
  90         cmake-utils_src_prepare
  91 }
  92
  93 multilib_src_configure() {
  94         local ffi_cflags ffi_ldflags
  95         if use libffi; then
  96                 ffi_cflags=$($(tc-getPKG_CONFIG) --cflags-only-I libffi)
  97                 ffi_ldflags=$($(tc-getPKG_CONFIG) --libs-only-L libffi)
  98         fi
  99
 100         local libdir=$(get_libdir)
 101         local mycmakeargs=(
 102                 # disable appending VCS revision to the version to improve
 103                 # direct cache hit ratio
 104                 -DLLVM_APPEND_VC_REV=OFF
 105                 -DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/lib/llvm/${SLOT}"
 106                 -DLLVM_LIBDIR_SUFFIX=${libdir#lib}
 107
 108                 -DBUILD_SHARED_LIBS=ON
 109                 -DLLVM_TARGETS_TO_BUILD="${LLVM_TARGETS// /;}"
 110                 -DLLVM_BUILD_TESTS=$(usex test)
 111
 112                 -DLLVM_ENABLE_FFI=$(usex libffi)
 113                 -DLLVM_ENABLE_LIBEDIT=$(usex libedit)
 114                 -DLLVM_ENABLE_TERMINFO=$(usex ncurses)
 115                 -DLLVM_ENABLE_LIBXML2=$(usex xml)
 116                 -DLLVM_ENABLE_ASSERTIONS=$(usex debug)
 117                 -DLLVM_ENABLE_EH=ON
 118                 -DLLVM_ENABLE_RTTI=ON
 119
 120                 -DWITH_POLLY=OFF # TODO
 121
 122                 -DLLVM_HOST_TRIPLE="${CHOST}"
 123
 124                 -DFFI_INCLUDE_DIR="${ffi_cflags#-I}"
 125                 -DFFI_LIBRARY_DIR="${ffi_ldflags#-L}"
 126                 # used only for llvm-objdump tool
 127                 -DHAVE_LIBXAR=$(multilib_native_usex xar 1 0)
 128
 129                 # disable OCaml bindings (now in dev-ml/llvm-ocaml)
 130                 -DOCAMLFIND=NO
 131         )
 132
 133 #       Note: go bindings have no CMake rules at the moment
 134 #       but let's kill the check in case they are introduced
 135 #       if ! multilib_is_native_abi || ! use go; then
 136                 mycmakeargs+=(
 137                         -DGO_EXECUTABLE=GO_EXECUTABLE-NOTFOUND
 138                 )
 139 #       fi
 140
 141         use test && mycmakeargs+=(
 142                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
 143         )
 144
 145         if multilib_is_native_abi; then
 146                 mycmakeargs+=(
 147                         -DLLVM_BUILD_DOCS=$(usex doc)
 148                         -DLLVM_ENABLE_OCAMLDOC=OFF
 149                         -DLLVM_ENABLE_SPHINX=$(usex doc)
 150                         -DLLVM_ENABLE_DOXYGEN=OFF
 151                         -DLLVM_INSTALL_UTILS=ON
 152                 )
 153                 use doc && mycmakeargs+=(
 154                         -DCMAKE_INSTALL_MANDIR="${EPREFIX}/usr/lib/llvm/${SLOT}/share/man"
 155                         -DLLVM_INSTALL_SPHINX_HTML_DIR="${EPREFIX}/usr/share/doc/${PF}/html"
 156                         -DSPHINX_WARNINGS_AS_ERRORS=OFF
 157                 )
 158                 use gold && mycmakeargs+=(
 159                         -DLLVM_BINUTILS_INCDIR="${EPREFIX}"/usr/include
 160                 )
 161         fi
 162
 163         if tc-is-cross-compiler; then
 164                 local tblgen="${EPREFIX}/usr/lib/llvm/${SLOT}/bin/llvm-tblgen"
 165                 [[ -x "${tblgen}" ]] \
 166                         || die "${tblgen} not found or usable"
 167                 mycmakeargs+=(
 168                         -DCMAKE_CROSSCOMPILING=ON
 169                         -DLLVM_TABLEGEN="${tblgen}"
 170                 )
 171         fi
 172
 173         # workaround BMI bug in gcc-7 (fixed in 7.4)
 174         # https://bugs.gentoo.org/649880
 175         # apply only to x86, https://bugs.gentoo.org/650506
 176         if tc-is-gcc && [[ ${MULTILIB_ABI_FLAG} == abi_x86* ]] &&
 177                         [[ $(gcc-major-version) -eq 7 && $(gcc-minor-version) -lt 4 ]]
 178         then
 179                 local CFLAGS="${CFLAGS} -mno-bmi"
 180                 local CXXFLAGS="${CXXFLAGS} -mno-bmi"
 181         fi
 182
 183         # LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
 184         use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
 185         cmake-utils_src_configure
 186 }
 187
 188 multilib_src_compile() {
 189         cmake-utils_src_compile
 190
 191         pax-mark m "${BUILD_DIR}"/bin/llvm-rtdyld
 192         pax-mark m "${BUILD_DIR}"/bin/lli
 193         pax-mark m "${BUILD_DIR}"/bin/lli-child-target
 194
 195         if use test; then
 196                 pax-mark m "${BUILD_DIR}"/unittests/ExecutionEngine/Orc/OrcJITTests
 197                 pax-mark m "${BUILD_DIR}"/unittests/ExecutionEngine/MCJIT/MCJITTests
 198                 pax-mark m "${BUILD_DIR}"/unittests/Support/SupportTests
 199         fi
 200 }
 201
 202 multilib_src_test() {
 203         # respect TMPDIR!
 204         local -x LIT_PRESERVES_TMP=1
 205         cmake-utils_src_make check
 206 }
 207
 208 src_install() {
 209         local MULTILIB_CHOST_TOOLS=(
 210                 /usr/lib/llvm/${SLOT}/bin/llvm-config
 211         )
 212
 213         local MULTILIB_WRAPPED_HEADERS=(
 214                 /usr/include/llvm/Config/llvm-config.h
 215         )
 216
 217         local LLVM_LDPATHS=()
 218         multilib-minimal_src_install
 219
 220         # move wrapped headers back
 221         mv "${ED%/}"/usr/include "${ED%/}"/usr/lib/llvm/${SLOT}/include || die
 222 }
 223
 224 multilib_src_install() {
 225         cmake-utils_src_install
 226
 227         # move headers to /usr/include for wrapping
 228         rm -rf "${ED%/}"/usr/include || die
 229         mv "${ED%/}"/usr/lib/llvm/${SLOT}/include "${ED%/}"/usr/include || die
 230
 231         LLVM_LDPATHS+=( "${EPREFIX}/usr/lib/llvm/${SLOT}/$(get_libdir)" )
 232 }
 233
 234 multilib_src_install_all() {
 235         local revord=$(( 9999 - ${SLOT} ))
 236         cat <<-_EOF_ > "${T}/10llvm-${revord}" || die
 237                 PATH="${EPREFIX}/usr/lib/llvm/${SLOT}/bin"
 238                 # we need to duplicate it in ROOTPATH for Portage to respect...
 239                 ROOTPATH="${EPREFIX}/usr/lib/llvm/${SLOT}/bin"
 240                 MANPATH="${EPREFIX}/usr/lib/llvm/${SLOT}/share/man"
 241                 LDPATH="$( IFS=:; echo "${LLVM_LDPATHS[*]}" )"
 242 _EOF_
 243         doenvd "${T}/10llvm-${revord}"
 244
 245         docompress "/usr/lib/llvm/${SLOT}/share/man"
 246 }