sys-devel/lld/lld-8.0.9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 : ${CMAKE_MAKEFILE_GENERATOR:=ninja}
   7 # (needed due to CMAKE_BUILD_TYPE != Gentoo)
   8 CMAKE_MIN_VERSION=3.7.0-r1
   9 PYTHON_COMPAT=( python2_7 )
  10
  11 inherit cmake-utils git-r3 llvm multiprocessing python-any-r1
  12
  13 DESCRIPTION="The LLVM linker (link editor)"
  14 HOMEPAGE="https://llvm.org/"
  15 SRC_URI=""
  16 EGIT_REPO_URI="https://git.llvm.org/git/lld.git
  17         https://github.com/llvm-mirror/lld.git"
  18 EGIT_BRANCH="release_80"
  19
  20 LICENSE="UoI-NCSA"
  21 SLOT="0"
  22 KEYWORDS=""
  23 IUSE="test"
  24 RESTRICT="!test? ( test )"
  25
  26 RDEPEND="~sys-devel/llvm-${PV}"
  27 DEPEND="${RDEPEND}
  28         test? ( $(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]") )"
  29
  30 # least intrusive of all
  31 CMAKE_BUILD_TYPE=RelWithDebInfo
  32
  33 python_check_deps() {
  34         has_version "dev-python/lit[${PYTHON_USEDEP}]"
  35 }
  36
  37 pkg_setup() {
  38         LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
  39         use test && python-any-r1_pkg_setup
  40 }
  41
  42 src_unpack() {
  43         if use test; then
  44                 # needed for patched gtest
  45                 git-r3_fetch "https://git.llvm.org/git/llvm.git
  46                         https://github.com/llvm-mirror/llvm.git"
  47         fi
  48         git-r3_fetch
  49
  50         if use test; then
  51                 git-r3_checkout https://llvm.org/git/llvm.git \
  52                         "${WORKDIR}"/llvm '' utils/{lit,unittest}
  53         fi
  54         git-r3_checkout
  55 }
  56
  57 src_configure() {
  58         local mycmakeargs=(
  59                 -DBUILD_SHARED_LIBS=ON
  60
  61                 -DLLVM_INCLUDE_TESTS=$(usex test)
  62         )
  63         use test && mycmakeargs+=(
  64                 -DLLVM_BUILD_TESTS=ON
  65                 -DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
  66                 -DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
  67                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
  68         )
  69
  70         cmake-utils_src_configure
  71 }
  72
  73 src_test() {
  74         cmake-utils_src_make check-lld
  75 }