sys-devel/autoconf/autoconf-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [[ ${PV} == "9999" ]] ; then
   7         EGIT_REPO_URI="https://git.savannah.gnu.org/git/autoconf.git"
   8         inherit git-r3
   9 else
  10         SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
  11                 ftp://alpha.gnu.org/pub/gnu/${PN}/${P}.tar.xz"
  12         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x86-linux"
  13 fi
  14
  15 inherit toolchain-autoconf
  16
  17 DESCRIPTION="Used to create autoconfiguration files"
  18 HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
  19
  20 LICENSE="GPL-3"
  21 SLOT="${PV}"
  22 IUSE="emacs"
  23
  24 BDEPEND=">=sys-devel/m4-1.4.16
  25         >=dev-lang/perl-5.6"
  26 RDEPEND="${BDEPEND}
  27         !~sys-devel/${P}:2.5
  28         >=sys-devel/autoconf-wrapper-13"
  29 [[ ${PV} == "9999" ]] && BDEPEND+=" >=sys-apps/texinfo-4.3"
  30 PDEPEND="emacs? ( app-emacs/autoconf-mode )"
  31
  32 src_prepare() {
  33         if [[ ${PV} == *9999 ]] ; then
  34                 # Avoid the "dirty" suffix in the git version by generating it
  35                 # before we run later stages which might modify source files.
  36                 local ver=$(./build-aux/git-version-gen .tarball-version)
  37                 echo "${ver}" > .tarball-version || die
  38
  39                 autoreconf -f -i || die
  40         fi
  41
  42         toolchain-autoconf_src_prepare
  43 }